app-i18n/libtabe: Port to EAPI 7

Bug: https://bugs.gentoo.org/697382
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/app-i18n/libtabe/libtabe-0.2.6.1.2.ebuild b/app-i18n/libtabe/libtabe-0.2.6.1.2.ebuild
index 3f33549ccf4bf691d5625ba59c230d8ec4121e8b..62e347d8caf93f09c83e3a51dc843f3708ca93c6 100644 (file)
--- a/app-i18n/libtabe/libtabe-0.2.6.1.2.ebuild
+++ b/app-i18n/libtabe/libtabe-0.2.6.1.2.ebuild
@@ -1,62 +1,71 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
 WANT_AUTOMAKE=1.11
 
-inherit eutils libtool autotools multilib versionator
+inherit autotools
 
-DEBIAN_PV=$(replace_version_separator 3 '-')
+DEBIAN_PV=$(ver_rs 3 '-')
 DEBIAN_PATCH=${PN}_${DEBIAN_PV}.diff
 ORIG_PV=${DEBIAN_PV%-*}
 ORIG_P=${PN}-${ORIG_PV}
 
 DESCRIPTION="Libtabe provides bimsphone support for xcin-2.5+"
 HOMEPAGE="https://packages.qa.debian.org/libt/libtabe.html"
-SRC_URI="mirror://debian/pool/main/${PN:0:4}/${PN}/${PN}_${ORIG_PV}.orig.tar.gz
+SRC_URI="
+       mirror://debian/pool/main/${PN:0:4}/${PN}/${PN}_${ORIG_PV}.orig.tar.gz
        mirror://debian/pool/main/${PN:0:4}/libtabe/${DEBIAN_PATCH}.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~ppc x86"
+KEYWORDS="amd64 ppc x86"
 IUSE="debug"
 
-DEPEND=">=sys-libs/db-4.5
+RDEPEND=">=sys-libs/db-4.5:="
+DEPEND="
+       ${RDEPEND}
        x11-libs/libX11"
 
 S=${WORKDIR}/${ORIG_P}.orig
 
-src_unpack() {
-       unpack ${A}
-       cd "${S}"
-       epatch "${WORKDIR}"/${DEBIAN_PATCH}
-       epatch "${FILESDIR}"/${ORIG_P}-fabs.patch
-       epatch "${FILESDIR}"/${ORIG_P}-ldflags.patch
+PATCHES=(
+       "${WORKDIR}"/${DEBIAN_PATCH}
+       "${FILESDIR}"/${ORIG_P}-fabs.patch
+       "${FILESDIR}"/${ORIG_P}-ldflags.patch
+)
 
-       ln -s script/configure.in . || die
+src_prepare() {
+       default
+
+       ln -s script/configure.in configure.ac || die
        eautoreconf
 }
 
-src_compile() {
-       myconf="--with-db-inc=/usr/include
-               --with-db-lib=/usr/$(get_libdir)
-               --with-db-bin=/usr/bin
-               --with-db-name=db
-               --enable-shared
-               --disable-static
-               $(use_enable debug)"
-
-       econf ${myconf}
+src_configure() {
+       econf \
+               --with-db-inc="${EPREFIX}"/usr/include \
+               --with-db-lib="${EPREFIX}"/usr/$(get_libdir) \
+               --with-db-bin="${EPREFIX}"/usr/bin \
+               --with-db-name=db \
+               --enable-shared \
+               --disable-static \
+               $(use_enable debug)
+}
 
+src_compile() {
        # We execute this serially because the Makefiles don't handle
        # proper cross-directory references.
-       for dir in src util tsi-src; do
-               emake -C ${dir} || die "make failed"
-       done
+       emake -C src
+       emake -C util
+       emake -C tsi-src
 }
 
 src_install() {
-       emake DESTDIR="${D}" install || die "emake install failed."
-       dodoc doc/* || die
+       default
+       dodoc -r doc/.
+
+       # no static archives
+       find "${D}" -name '*.la' -delete || die
 }