DIST qt-creator-opensource-src-3.6.1.tar.gz 23144233 SHA256 e53611f80332cd1d171a9b91f8467b6182186cbec6b4a9301f32367368f15de2 SHA512 be869de5fdaf7294dca95e540b7b9228015132071aaf5315a3c8b2da3043a03528b3d75e94a7fffc567bd802dba1a48568c4a335926c1d5e1e18beaae48ecc9f WHIRLPOOL c62cb18d5c9be0fac2ea9ef355d820a29183e3b0226c1fb70bef9dc7402dd16886ceacd4029764204bde4595d77098641080ad8fdf4f58e97ebb96e3abf3ae65
DIST qt-creator-opensource-src-4.0.3.tar.gz 21972901 SHA256 a213a9b66e7e0eb906036a1587256fc0f7bac33912d9ae5e6117459231f56449 SHA512 7b06b9d2cb050008cbbceeb2f18ad2264a2366db9ad37474b63d0a6d30a3bde86ecb770678beb88af4d5be7550e947c689d23956e2062796cbf9476006c0528a WHIRLPOOL 7d515a038dec69980305a43545d952a1083f00add756e82cd0b568bc2c31c8eb81667822295b352cad2c54c3a447a31e9c8203db25d945023fc70ff2f0d01cd5
DIST qt-creator-opensource-src-4.1.0.tar.xz 16291164 SHA256 d00f84539203c8456a6ebca149228cd22d1bae7f41c95c88f6fc63a02aeed8c3 SHA512 73d1d73d80faeb8ce9052f23720bbc312214256d3b9867447058ce878dca85457ba6f9c69281b95f622f8bc3d9c1739641960c48c6eebba3c48806126e6b57cf WHIRLPOOL 84521639a1054d294144f181175ed696c86d37e1a67373f5e6dbf147a99b2ff9d5216630bce2c91178c066f42778b658e7bd21fd5c9e1b5143183d6986f6c7fc
+DIST qt-creator-opensource-src-4.2.0.tar.xz 16624096 SHA256 203e2bc6618590b5e5a7e17f1a05e65b255d742f0b8f0ba3246fb541dfdfbe80 SHA512 1801611d8db10041332d728a2af6b0c57b28b3ab9847a8875edb788d3b0fe6570103a408a7f52c989e40949743263d444e5db49d290860f2e7231f463fa86f7a WHIRLPOOL 841fb63bb6d25a640fb8db24412b05b93e9240db8c68de9555cc4baef50d6e08d13594f4e7cc675fda90359d8a4a4fbb8110f9cfd73315e1775a636f5f28a54d
<flag name="glsl">Enable GLSL source code editor</flag>
<flag name="ios">Build plugin for Apple iOS devices</flag>
<flag name="mercurial">Add support for <pkg>dev-vcs/mercurial</pkg> version control system</flag>
- <flag name="modeling">Enable graphical model editor plugin</flag>
+ <flag name="modeling">Enable graphical model editor</flag>
<flag name="nim">Enable Nim source code editor</flag>
<flag name="perforce">Add support for Perforce version control system (requires manual installation of Perforce client)</flag>
<flag name="python">Enable Python source code editor</flag>
<flag name="qbs">Enable QBS project manager plugin</flag>
<flag name="qnx">Build plugin for QNX devices</flag>
+ <flag name="scxml">Enable graphical SCXML editor</flag>
<flag name="systemd">Add support for retrieving application output from journald</flag>
<flag name="valgrind">Add support for memory debugging using <pkg>dev-util/valgrind</pkg></flag>
<flag name="webengine">Use <pkg>dev-qt/qtwebengine</pkg> to view documentation</flag>
clangcodemodel? ( >=sys-devel/clang-3.8.0:= )
qbs? ( ~dev-util/qbs-1.6.1 )
systemd? ( sys-apps/systemd:= )
- webengine? ( >=dev-qt/qtwebengine-${QT_PV} )
+ webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
webkit? ( >=dev-qt/qtwebkit-${QT_PV} )
"
DEPEND="${RDEPEND}
doc? ( >=dev-qt/qdoc-${QT_PV} )
test? ( >=dev-qt/qttest-${QT_PV} )
"
-# qt translations must be installed for qt-creator translations to work
+# qt translations must also be installed or qt-creator translations won't be loaded
for x in ${PLOCALES}; do
RDEPEND+=" linguas_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
done
--- /dev/null
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PLOCALES="cs de fr ja pl ru sl uk zh_CN zh_TW"
+
+inherit eutils l10n qmake-utils toolchain-funcs virtualx xdg
+
+DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
+HOMEPAGE="http://doc.qt.io/qtcreator/"
+LICENSE="GPL-3"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI=(
+ "git://code.qt.io/${PN}/${PN}.git"
+ "https://code.qt.io/git/${PN}/${PN}.git"
+ )
+else
+ MY_PV=${PV/_/-}
+ MY_P=${PN}-opensource-src-${MY_PV}
+ [[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
+ SRC_URI="http://download.qt.io/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.xz"
+ KEYWORDS="~amd64 ~arm ~x86"
+ S=${WORKDIR}/${MY_P}
+fi
+
+# TODO: unbundle sqlite
+
+QTC_PLUGINS=('android:android|qmakeandroidsupport' autotools:autotoolsprojectmanager baremetal bazaar
+ clangcodemodel clangstaticanalyzer clearcase cmake:cmakeprojectmanager cvs git glsl:glsleditor
+ ios mercurial modeling:modeleditor nim perforce python:pythoneditor qbs:qbsprojectmanager qnx
+ scxml:scxmleditor subversion valgrind winrt)
+IUSE="doc systemd test +webengine ${QTC_PLUGINS[@]%:*}"
+
+# minimum Qt version required
+QT_PV="5.6.0:5"
+
+RDEPEND="
+ =dev-libs/botan-1.10*[-bindist,threads]
+ >=dev-qt/designer-${QT_PV}
+ >=dev-qt/qtconcurrent-${QT_PV}
+ >=dev-qt/qtcore-${QT_PV}
+ >=dev-qt/qtdeclarative-${QT_PV}[widgets]
+ >=dev-qt/qtgui-${QT_PV}
+ >=dev-qt/qthelp-${QT_PV}
+ >=dev-qt/qtnetwork-${QT_PV}[ssl]
+ >=dev-qt/qtprintsupport-${QT_PV}
+ >=dev-qt/qtquickcontrols-${QT_PV}
+ >=dev-qt/qtscript-${QT_PV}
+ >=dev-qt/qtsql-${QT_PV}[sqlite]
+ >=dev-qt/qtsvg-${QT_PV}
+ >=dev-qt/qtwidgets-${QT_PV}
+ >=dev-qt/qtx11extras-${QT_PV}
+ >=dev-qt/qtxml-${QT_PV}
+ sys-devel/gdb[client,python]
+ clangcodemodel? ( >=sys-devel/clang-3.9:= )
+ qbs? ( =dev-util/qbs-1.7* )
+ systemd? ( sys-apps/systemd:= )
+ webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
+"
+DEPEND="${RDEPEND}
+ >=dev-qt/linguist-tools-${QT_PV}
+ virtual/pkgconfig
+ doc? ( >=dev-qt/qdoc-${QT_PV} )
+ test? (
+ >=dev-qt/qtdeclarative-${QT_PV}[localstorage,xml]
+ >=dev-qt/qtquickcontrols2-${QT_PV}
+ >=dev-qt/qttest-${QT_PV}
+ )
+"
+# qt translations must also be installed or qt-creator translations won't be loaded
+for x in ${PLOCALES}; do
+ RDEPEND+=" linguas_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
+done
+unset x
+
+PDEPEND="
+ autotools? ( sys-devel/autoconf )
+ bazaar? ( dev-vcs/bzr )
+ clangstaticanalyzer? ( >=sys-devel/clang-3.9 )
+ cmake? ( dev-util/cmake )
+ cvs? ( dev-vcs/cvs )
+ git? ( dev-vcs/git )
+ mercurial? ( dev-vcs/mercurial )
+ subversion? ( dev-vcs/subversion )
+ valgrind? ( dev-util/valgrind )
+"
+
+src_unpack() {
+ if tc-is-gcc; then
+ if [[ $(gcc-major-version) -lt 4 ]] || \
+ [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -lt 8 ]]; then
+ eerror "GCC version 4.8 or later is required to build Qt Creator ${PV}"
+ die "GCC >= 4.8 required"
+ fi
+ fi
+
+ if [[ ${PV} == *9999 ]]; then
+ git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+
+ # disable unwanted plugins
+ for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
+ if ! use ${plugin%:*}; then
+ einfo "Disabling ${plugin%:*} plugin"
+ sed -i -re "/(^\s+|SUBDIRS\s*\+=\s*)(${plugin#*:})\>/d" \
+ src/plugins/plugins.pro || die "failed to disable ${plugin%:*} plugin"
+ fi
+ done
+
+ # avoid building unused support libraries
+ if ! use clangcodemodel; then
+ sed -i -e '/clangbackendipc/d' src/libs/libs.pro || die
+ fi
+ if ! use glsl; then
+ sed -i -e '/glsl/d' src/libs/libs.pro || die
+ fi
+ if ! use modeling; then
+ sed -i -e '/modelinglib/d' src/libs/libs.pro || die
+ fi
+
+ # automagic dep on qtwebengine
+ if ! use webengine; then
+ sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' src/plugins/help/help.pro || die
+ fi
+
+ # disable broken or unreliable tests
+ sed -i -e '/SUBDIRS/ s/\<dumpers\>//' tests/auto/debugger/debugger.pro || die
+ sed -i -e '/CONFIG -=/ s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
+ sed -i -e '/\(^char qmlString\|states\.qml$\)/ i return;' tests/auto/qml/qmldesigner/coretests/tst_testcore.cpp || die
+ sed -i -e 's/\<timeline\(items\|notes\|selection\)renderpass\>//' tests/auto/timeline/timeline.pro || die
+ sed -i -e 's/\<memcheck\>//' tests/auto/valgrind/valgrind.pro || die
+
+ # fix translations
+ sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
+ share/qtcreator/translations/translations.pro || die
+
+ # remove bundled qbs
+ rm -rf src/shared/qbs || die
+}
+
+src_configure() {
+ eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
+ IDE_PACKAGE_MODE=1 \
+ $(use clangcodemodel && echo LLVM_INSTALL_DIR="${EPREFIX}/usr") \
+ $(use qbs && echo QBS_INSTALL_DIR="${EPREFIX}/usr") \
+ CONFIG+=qbs_disable_rpath \
+ CONFIG+=qbs_enable_project_file_updates \
+ $(use systemd && echo CONFIG+=journald) \
+ $(use test && echo BUILD_TESTS=1) \
+ USE_SYSTEM_BOTAN=1
+}
+
+src_test() {
+ cd tests/auto && virtx default
+}
+
+src_install() {
+ emake INSTALL_ROOT="${ED}usr" install
+
+ dodoc dist/{changes-*,known-issues}
+
+ # install documentation
+ if use doc; then
+ emake docs
+ # don't use ${PF} or the doc will not be found
+ insinto /usr/share/doc/qtcreator
+ doins share/doc/qtcreator/qtcreator{,-dev}.qch
+ docompress -x /usr/share/doc/qtcreator/qtcreator{,-dev}.qch
+ fi
+
+ # create a desktop file
+ make_desktop_entry qtcreator 'Qt Creator' QtProject-qtcreator 'Development;IDE;Qt;' \
+ 'MimeType=text/x-c++src;text/x-c++hdr;text/x-xsrc;application/x-designer;application/vnd.qt.qmakeprofile;application/vnd.qt.xml.resource;text/x-qml;text/x-qt.qml;text/x-qt.qbs;'
+}
QTC_PLUGINS=('android:android|qmakeandroidsupport' autotools:autotoolsprojectmanager baremetal bazaar
clangcodemodel clangstaticanalyzer clearcase cmake:cmakeprojectmanager cvs git glsl:glsleditor
ios mercurial modeling:modeleditor nim perforce python:pythoneditor qbs:qbsprojectmanager qnx
- subversion valgrind winrt)
-IUSE="doc systemd test webengine webkit ${QTC_PLUGINS[@]%:*}"
-
-REQUIRED_USE="?? ( webengine webkit )"
+ scxml:scxmleditor subversion valgrind winrt)
+IUSE="doc systemd test +webengine ${QTC_PLUGINS[@]%:*}"
# minimum Qt version required
QT_PV="5.6.0:5"
>=dev-qt/qtx11extras-${QT_PV}
>=dev-qt/qtxml-${QT_PV}
sys-devel/gdb[client,python]
- clangcodemodel? ( >=sys-devel/clang-3.8.0:= )
- qbs? ( >=dev-util/qbs-1.6.0 )
+ clangcodemodel? ( >=sys-devel/clang-3.9:= )
+ qbs? ( >=dev-util/qbs-1.7.0 )
systemd? ( sys-apps/systemd:= )
- webengine? ( >=dev-qt/qtwebengine-${QT_PV} )
- webkit? ( >=dev-qt/qtwebkit-${QT_PV} )
+ webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
"
DEPEND="${RDEPEND}
>=dev-qt/linguist-tools-${QT_PV}
virtual/pkgconfig
doc? ( >=dev-qt/qdoc-${QT_PV} )
- test? ( >=dev-qt/qttest-${QT_PV} )
+ test? (
+ >=dev-qt/qtdeclarative-${QT_PV}[localstorage,xml]
+ >=dev-qt/qtquickcontrols2-${QT_PV}
+ >=dev-qt/qttest-${QT_PV}
+ )
"
-# qt translations must be installed for qt-creator translations to work
+# qt translations must also be installed or qt-creator translations won't be loaded
for x in ${PLOCALES}; do
RDEPEND+=" linguas_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
done
PDEPEND="
autotools? ( sys-devel/autoconf )
bazaar? ( dev-vcs/bzr )
- clangstaticanalyzer? ( >=sys-devel/clang-3.8.0 )
+ clangstaticanalyzer? ( >=sys-devel/clang-3.9 )
cmake? ( dev-util/cmake )
cvs? ( dev-vcs/cvs )
git? ( dev-vcs/git )
sed -i -e '/modelinglib/d' src/libs/libs.pro || die
fi
- # automagic dep on qtwebkit (bug 538236)
- if ! use webkit; then
- sed -i -e 's/isEmpty(QT\.webkitwidgets\.name)/true/' \
- src/plugins/help/help.pro || die "failed to disable webkit"
- fi
-
# automagic dep on qtwebengine
if ! use webengine; then
- sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' \
- src/plugins/help/help.pro || die "failed to disable webengine"
+ sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' src/plugins/help/help.pro || die
fi
# disable broken or unreliable tests
sed -i -e '/SUBDIRS/ s/\<dumpers\>//' tests/auto/debugger/debugger.pro || die
sed -i -e '/CONFIG -=/ s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
- sed -i -e '/SUBDIRS/ s/\<memcheck\>//' tests/auto/valgrind/valgrind.pro || die
+ sed -i -e '/\(^char qmlString\|states\.qml$\)/ i return;' tests/auto/qml/qmldesigner/coretests/tst_testcore.cpp || die
+ sed -i -e 's/\<timeline\(items\|notes\|selection\)renderpass\>//' tests/auto/timeline/timeline.pro || die
+ sed -i -e 's/\<memcheck\>//' tests/auto/valgrind/valgrind.pro || die
# fix translations
sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
# Distributed under the terms of the GNU General Public License v2
# $Id$
+# Davide Pesavento <pesa@gentoo.org> (19 Dec 2016)
+# Various unkeyworded deps: >=sys-devel/clang-3.9 (#591822),
+# dev-qt/qtquickcontrols2 (#603054), dev-qt/qtwebengine (#581478)
+dev-qt/qt-creator clangcodemodel clangstaticanalyzer test webengine
+
# James Le Cuirot <chewi@gentoo.org> (14 Dec 2016)
# DOSBox + OpenGLide is untested on this arch.
games-emulation/dosbox glide
# does not build on arm at all (upstream bug)
dev-scheme/racket futures jit
-# Davide Pesavento <pesa@gentoo.org> (13 May 2016)
-# dev-qt/qtwebengine:5 not keyworded, bug 581478
-dev-qt/qt-creator webengine
-
# Patrick McLean <chutzpah@gentoo.org> (12 May 2016)
# Tests require dev-python/tox which isn't keyworded on arm
sys-cluster/ceph test
# Distributed under the terms of the GNU General Public License v2
# $Id$
+# Davide Pesavento <pesa@gentoo.org> (19 Dec 2016)
+# Various unkeyworded deps: >=sys-devel/clang-3.9 (#591822),
+# dev-qt/qtquickcontrols2 (#603054), dev-qt/qtwebengine (#581478)
+dev-qt/qt-creator clangcodemodel clangstaticanalyzer test webengine
+
# Davide Pesavento <pesa@gentoo.org> (28 Jul 2016)
# The corresponding Qt5 modules are not keyworded on arm, and we don't want to
# keyword them solely because of PyQt5 while there are no other in-tree users.
dev-python/PyQt5 location webengine
-# Davide Pesavento <pesa@gentoo.org> (13 May 2016)
-# dev-qt/qtwebengine:5 not keyworded, bug 581478
-dev-qt/qt-creator webengine
-
# Thomas Deutschmann <whissi@whissi.de> (25 Apr 2016), on behalf of
# Ian Delaney <idella4@gentoo.org> (25 Apr 2016)
# for the proxy-maintainers project
projects / gentoo.git / commitdiff