dev-util/pkgcheck: version bump to 0.6.5

Signed-off-by: Tim Harder <radhermit@gentoo.org>

diff --git a/dev-util/pkgcheck/Manifest b/dev-util/pkgcheck/Manifest
index b60ce6afff176e8b91526f85d2fe51ff315d741c..8b2c77a9900ffc652a3c72d636b7a7949f079a1d 100644 (file)
--- a/dev-util/pkgcheck/Manifest
+++ b/dev-util/pkgcheck/Manifest
@@ -1 +1,2 @@
 DIST pkgcheck-0.6.4.tar.gz 174315 BLAKE2B 147745f8dc7df3c47302b2b48a1ed0bbeec348cafbe4c7ca247c688db25b248a6d079c73e4ffc28fead4a06fc2f09aa57e8dbffffcbc765602e8d433141eaeaa SHA512 94cceccd5b184c5b810c298faa1071ec77b8ca2a618e7620dec933ea5da7beda3cb5f96a4efaf7ceb2f2059040e9ef0cbd974613011b816c10f28e59c5d32a00
+DIST pkgcheck-0.6.5.tar.gz 181861 BLAKE2B cf74c691878b3b409a7d88e0960e24dd7f1ba9d7e04eceef7f372241998721e47090aa21e46e71c5191ff2ff86392a3528c2f570b65a9b78809376a657073cb4 SHA512 e8dfd9b0e842df3bdc8044581f7bb9be6d2e671164c5966751d5df071ce3759f45f675b93ec5cfeb05362f4ba3a8a50670151068bcc6713b53e11f94d360bc18

diff --git a/dev-util/pkgcheck/pkgcheck-0.6.5.ebuild b/dev-util/pkgcheck/pkgcheck-0.6.5.ebuild
new file mode 100644 (file)
index 0000000..7a5d1a9
--- /dev/null
+++ b/dev-util/pkgcheck/pkgcheck-0.6.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/pkgcore/pkgcheck.git"
+       inherit git-r3
+else
+       KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+       SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="pkgcore-based QA utility"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+if [[ ${PV} == *9999 ]]; then
+       RDEPEND="
+               ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+               ~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+       RDEPEND="
+               >=dev-python/snakeoil-0.8.3[${PYTHON_USEDEP}]
+               >=sys-apps/pkgcore-0.10.4[${PYTHON_USEDEP}]"
+fi
+RDEPEND+="
+       dev-python/chardet[${PYTHON_USEDEP}]
+       dev-python/lxml[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_compile_all() {
+       use doc && esetup.py build_man
+}
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       local DOCS=( AUTHORS NEWS.rst )
+       esetup.py install_docs \
+               --docdir="${ED%/}/usr/share/doc/${PF}" \
+               --mandir="${ED%/}/usr/share/man"
+       distutils-r1_python_install_all
+}

diff --git a/dev-util/pkgcheck/pkgcheck-9999.ebuild b/dev-util/pkgcheck/pkgcheck-9999.ebuild
index 3d30a06c6c246361a49fdd45d977ca43df443f5d..7a5d1a9d7fd6d770271d551405e4843546ccd14e 100644 (file)
--- a/dev-util/pkgcheck/pkgcheck-9999.ebuild
+++ b/dev-util/pkgcheck/pkgcheck-9999.ebuild
@@ -29,7 +29,7 @@ if [[ ${PV} == *9999 ]]; then
 else
        RDEPEND="
                >=dev-python/snakeoil-0.8.3[${PYTHON_USEDEP}]
-               >=sys-apps/pkgcore-0.10.3[${PYTHON_USEDEP}]"
+               >=sys-apps/pkgcore-0.10.4[${PYTHON_USEDEP}]"
 fi
 RDEPEND+="
        dev-python/chardet[${PYTHON_USEDEP}]