mail-filter/anubis: version bump

gpgme may be broken.

Bug: 575936

Package-Manager: Portage-2.3.3, Repoman-2.3.1

diff --git a/mail-filter/anubis/Manifest b/mail-filter/anubis/Manifest
index 55068622287d950fb21e2c1f134920d947dacbc8..bebb7518fd4437443ef4870d97bd41e4cf130863 100644 (file)
--- a/mail-filter/anubis/Manifest
+++ b/mail-filter/anubis/Manifest
@@ -1 +1,2 @@
 DIST anubis-4.1.1.tar.gz 1104272 SHA256 93ef7a2d8bc3b50cd2e228cfe27e296ee14accadf8533bad9b2beee88a96e8fa SHA512 51e9c3a4cc4f217348522ba196daf26908f5ebed1abbe8c3f4c876847284e1f43f19d5cc68cde3cae5aacc55d42b7a6786f9afb23856c647ddf6d6c4b6c0a7a7 WHIRLPOOL 316e6d19b87b80f4f7c97899972deb31ca6d1797abb28d9a5eb4b8792f324bd69bf84a1f978e37cd4d98cbeead01a27cdb53a670a7e25d8ac2ed7860492a5b86
+DIST anubis-4.2.tar.gz 1623768 SHA256 5f3a2dd77c5ef52a593428c5b6d0042c1746eb8262c31bde9ee67455f8aad6d6 SHA512 cd16b67780b37f02a31374875763a1d54107289fbaf53160de5778f095b56bdb390c72a06fc067d87556b1158b0134c0fc88d30edbe124a71d8c80a89595e75f WHIRLPOOL f94e3afd6c6c74645d68b42c0d01a235b742e1efdab04bd883286756e751386e2defacf6d1c06dcb26f4ff4fa83f9a351ad81d4decf9ba98e8f6d136a2f69eb3

diff --git a/mail-filter/anubis/anubis-4.2.ebuild b/mail-filter/anubis/anubis-4.2.ebuild
new file mode 100644 (file)
index 0000000..6a3586b
--- /dev/null
+++ b/mail-filter/anubis/anubis-4.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils pam toolchain-funcs user
+
+DESCRIPTION="GNU Anubis is an outgoing mail processor"
+HOMEPAGE="https://www.gnu.org/software/anubis/"
+
+SRC_URI="mirror://gnu/anubis/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="crypt guile mysql postgres nls pam pcre sasl socks5 +gnutls tcpd test"
+
+RDEPEND="sys-libs/gdbm
+       crypt? ( >=app-crypt/gpgme-1.8.0 )
+       guile? ( >=dev-scheme/guile-1.8 )
+       mysql? ( virtual/mysql )
+       pam? ( virtual/pam )
+       postgres? ( dev-db/postgresql:*[server] )
+       nls? ( sys-devel/gettext )
+       pcre? ( >=dev-libs/libpcre-3.9 )
+       sasl? ( virtual/gsasl )
+       gnutls? ( net-libs/gnutls )
+       tcpd? ( >=sys-apps/tcp-wrappers-7.6 )"
+DEPEND="${RDEPEND}
+       test? ( dev-util/dejagnu )"
+
+REQUIRED_USE="mysql? ( sasl )
+       postgres? ( sasl )"
+
+pkg_setup() {
+       enewuser anubis
+}
+
+src_configure() {
+       econf --with-unprivileged-user=anubis \
+               --disable-rpath \
+               $(use_with mysql) \
+               $(use_with postgres) \
+               $(use_with pam) \
+               $(use_with pcre) \
+               $(use_enable nls) \
+               $(use_with guile) \
+               $(use_with sasl gsasl) \
+               $(use_with gnutls) \
+               $(use_with tcpd tcp-wrappers) \
+               $(use_with socks5 socks-proxy) \
+               $(use_with crypt gpgme)
+}
+
+src_test() {
+       emake -C testsuite check
+}
+
+src_install() {
+       default
+       docinto examples
+       dodoc examples/*anubis*
+       docinto guile
+       dodoc guile/*.scm
+
+       use pam  && pamd_mimic system-auth anubis auth account session
+}