dev-libs/libgpg-error: eapi bump

Package-Manager: Portage-2.3.49, Repoman-2.3.10
Signed-off-by: Alon Bar-Lev <alonbl@gentoo.org>

diff --git a/dev-libs/libgpg-error/libgpg-error-1.32-r1.ebuild b/dev-libs/libgpg-error/libgpg-error-1.32-r1.ebuild
new file mode 100644 (file)
index 0000000..054a464
--- /dev/null
+++ b/dev-libs/libgpg-error/libgpg-error-1.32-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool multilib-minimal toolchain-funcs
+
+DESCRIPTION="Contains error handling functions used by GnuPG software"
+HOMEPAGE="http://www.gnupg.org/related_software/libgpg-error"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="common-lisp nls static-libs"
+
+RDEPEND="nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+MULTILIB_CHOST_TOOLS=(
+       /usr/bin/gpg-error-config
+)
+MULTILIB_WRAPPED_HEADERS=(
+       /usr/include/gpg-error.h
+       /usr/include/gpgrt.h
+)
+
+src_prepare() {
+       default
+       elibtoolize
+}
+
+multilib_src_configure() {
+       ECONF_SOURCE="${S}" econf \
+               $(multilib_is_native_abi || echo --disable-languages) \
+               $(use_enable common-lisp languages) \
+               $(use_enable nls) \
+               $(use_enable static-libs static) \
+               --enable-threads \
+               CC_FOR_BUILD="$(tc-getBUILD_CC)"
+}
+
+multilib_src_install_all() {
+       einstalldocs
+       find "${D}" -name '*.la' -delete || die
+}