app-emulation/winetricks: Version bump to 20160329.

Also bump to EAPI 6 across versions, in addition to minor
formatting/wording tweaks.

Package-Manager: portage-2.2.28

diff --git a/app-emulation/winetricks/Manifest b/app-emulation/winetricks/Manifest
index b78a50da93231c111b2c7fec951865a2a1a22509..8cf05191eaa2844000ae285d3a9b07dc7e7b0a47 100644 (file)
--- a/app-emulation/winetricks/Manifest
+++ b/app-emulation/winetricks/Manifest
@@ -1,2 +1,3 @@
 DIST winetricks-20160109.tar.gz 176741 SHA256 6a55db3c1441021bfcb8653b3f0c6eb4260e1ab22fbe98083d28f21470f0ca71 SHA512 41fd0f7bfa2155131d26eb185a584d6e276931f6cc22341847690fa82d3f35e0c9fdeec877a5dc6d4d6092d6a15299e98015be9aaa84677cd5442fbff4fa3891 WHIRLPOOL f6bfa5596c855a942a1ffebcc6252274c379187a9763c036795b3e431ccdcadb7116e48e23ac3109547d96e5cfa9302c3d99a911190ac0d70b073d355974f95e
+DIST winetricks-20160329.tar.gz 170236 SHA256 a2a6f93e5242c22dd284710d26d6c98169eebcd57e5db71dae4c8e4fbad34c39 SHA512 e128a8ec1422c2864ef8919f26e1218ea1b663a5ebac789669b1451616213e406f474ed29f160bdcbfa5357475d43ffc9ee6d4587548ca10f23376759150812e WHIRLPOOL bf1abe3cf8d4f10c7f28112f583d825f70bfc3b4a77386b7e463e73a74713067f77a8f30714d476b464e8d8a8ed1f70d4b203a75f34904821c7bfa75860a557b
 DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 SHA256 dded8c294cc5c2e71e4a5d1531ab165178cf3d2d1d890d0656368c2e499bfeb9 SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a WHIRLPOOL 268da9e06712a678fbbcfff8eac1fca364b5e46f0a9c48a591eb88f03260b1a55f203eb2908bfe1f0a534b77c866127ff6f7049b0e43fe8abeaaa26fe55de75b

diff --git a/app-emulation/winetricks/winetricks-20160329.ebuild b/app-emulation/winetricks/winetricks-20160329.ebuild
new file mode 100644 (file)
index 0000000..b8aef92
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-20160329.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit gnome2-utils eutils
+
+if [[ ${PV} == "99999999" ]] ; then
+       EGIT_REPO_URI="git://github.com/Winetricks/${PN}.git"
+       inherit git-r3
+       SRC_URI=""
+else
+       SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+wtg=winetricks-gentoo-2012.11.24
+
+SRC_URI="${SRC_URI}
+       gtk? ( https://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )
+       kde? ( https://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="http://winetricks.org http://wiki.winehq.org/winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar"
+
+DEPEND=""
+RDEPEND="app-arch/cabextract
+       app-arch/p7zip
+       app-arch/unzip
+       app-emulation/wine
+       net-misc/wget
+       x11-misc/xdg-utils
+       gtk? ( gnome-extra/zenity )
+       kde? ( kde-apps/kdialog )
+       rar? ( app-arch/unrar )"
+
+# Uses a non-standard "Wine" category, which is provided by app-emulation/wine; #451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+# Tests require network access and run Wine, which is unreliable from a portage environment.
+RESTRICT="test"
+
+src_unpack() {
+       if [[ ${PV} == "99999999" ]] ; then
+               git-r3_src_unpack
+               if use gtk || use kde; then
+                       unpack ${wtg}.tar.bz2
+               fi
+       else
+               default
+       fi
+}
+
+src_install() {
+       default
+       if use gtk || use kde; then
+               cd "${WORKDIR}/${wtg}" || die
+               domenu winetricks.desktop
+               insinto /usr/share/icons/hicolor/scalable/apps
+               doins wine-winetricks.svg
+       fi
+}
+
+pkg_preinst() {
+       if use gtk || use kde; then
+               gnome2_icon_savelist
+       fi
+}
+
+pkg_postinst() {
+       if use gtk || use kde; then
+               gnome2_icon_cache_update
+       fi
+}
+
+pkg_postrm() {
+       if use gtk || use kde; then
+               gnome2_icon_cache_update
+       fi
+}

diff --git a/app-emulation/winetricks/winetricks-99999999.ebuild b/app-emulation/winetricks/winetricks-99999999.ebuild
index dba352c251d92d427cae698cb46c37c21d521f03..45214564b7f7d63b8747f630d51708c2c7b189de 100644 (file)
--- a/app-emulation/winetricks/winetricks-99999999.ebuild
+++ b/app-emulation/winetricks/winetricks-99999999.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
 inherit gnome2-utils eutils
 
@@ -14,7 +14,9 @@ else
        SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
        KEYWORDS="~amd64 ~x86"
 fi
+
 wtg=winetricks-gentoo-2012.11.24
+
 SRC_URI="${SRC_URI}
        gtk? ( https://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )
        kde? ( https://dev.gentoo.org/~tetromino/distfiles/wine/${wtg}.tar.bz2 )"
@@ -40,7 +42,7 @@ RDEPEND="app-arch/cabextract
 # Uses non-standard "Wine" category, which is provided by app-emulation/wine; #451552
 QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
 
-# Tests require network access and run wine, which is unreliable from a portage environment
+# Tests require network access and run Wine, which is unreliable from a portage environment.
 RESTRICT="test"
 
 src_unpack() {