dev-python/gitdb: Bump to 4.0.2, py3.{7,8}

Closes: https://bugs.gentoo.org/711994
Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/dev-python/gitdb/Manifest b/dev-python/gitdb/Manifest
index 5a52a2ccc2fdcb9801aa48a37cf2bf0520ef422c..a5883d4a6a0c24f9d492d5993f7cd26e405da003 100644 (file)
--- a/dev-python/gitdb/Manifest
+++ b/dev-python/gitdb/Manifest
@@ -1 +1,2 @@
 DIST gitdb-0.6.4.tar.gz 400506 BLAKE2B 5c6f1bf15e597267bcefa6f77bf4829f13673a0f6e463b2d62a469cee3cf8de866bd88a59d9308211a03587fca18610b10a044d579abc976f40f8e1591b4f292 SHA512 2314ae70ec26c46c559cc69a1300ead8cd65a0a22425a3bb36b04edb73bd5e2628cbdcd8e515830c74b21af2badea662c915a727d9a46ed2f92f169eb71bdf62
+DIST gitdb-4.0.2.tar.gz 395032 BLAKE2B 0a9cff81fe1e7e8273938545c297096be181dab4ef8e771260f78c2921bcdbf929deb453d7fc893050eb93aba54a8d8a6dabf2e553892d7a9544dbb3e35b44b7 SHA512 9375710ede3f3df7c4d2b0f144d7843cec436b7128c1093c9575ceb62ee03c9f6a12941c97f8642cd8d1b8a429258ac612a78be402bf40decd4b4b5ae2e0d2a9

diff --git a/dev-python/gitdb/gitdb-4.0.2.ebuild b/dev-python/gitdb/gitdb-4.0.2.ebuild
new file mode 100644 (file)
index 0000000..16cea18
--- /dev/null
+++ b/dev-python/gitdb/gitdb-4.0.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="GitDB is a pure-Python git object database"
+HOMEPAGE="
+       https://github.com/gitpython-developers/gitdb
+       https://pypi.org/project/gitdb/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+       >=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+       test? (
+               dev-vcs/git
+       )"
+
+distutils_enable_tests nose
+
+src_test() {
+       local i
+
+       mkdir "${T}"/repo || die
+       cd "${T}"/repo || die
+
+       for (( i = 0; i < 2500; ++i )); do
+               echo "${i}" > file"${i}" || die
+       done
+
+       git init || die
+       git config user.email "you@example.com" || die
+       git config user.name "Your Name" || die
+       git add -A || die
+       git commit -q -m ".." || die
+       git clone --bare "${T}"/repo "${T}"/repo.git || die
+       cd "${S}" || die
+
+       distutils-r1_src_test
+}
+
+python_test() {
+       #TRAVIS=1 disables performance tests which rely on the gitdb repo
+       local -x TRAVIS=1
+       local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
+       nosetests -v || die "Tests fail with ${EPYTHON}"
+}