dev-python/bpython: bump to 0.19

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

diff --git a/dev-python/bpython/Manifest b/dev-python/bpython/Manifest
index f320511b490f5feaf24b6125108a1f447ad7325a..fb82fbfea500a39e41ff38ac132d3d74226a75ce 100644 (file)
--- a/dev-python/bpython/Manifest
+++ b/dev-python/bpython/Manifest
@@ -1 +1,2 @@
 DIST bpython-0.18.tar.gz 213321 BLAKE2B 476c18fbec1d4ef3c5e206e7586b0e982656160474b64ceaecf5b49f560115af0e51d964553aad25bc765f7b431bc4f062581f9f30c0cb2e8da51cdbf2bca5ca SHA512 760143c286e686d4b8d706e38f3b2d2e7c865f960fa8d828ec08a7d0dd198bfa09686ab3c4b27ea365400d60c45b69a3c03ee726879a8825cc91af2a75d28dab
+DIST bpython-0.19.tar.gz 216564 BLAKE2B a0b469ae28965e7926838b2d520aed0199a39ad5d9d5650e34446601e6e5f023a6c09cbdd85a30b2873dc72b5ef5774c483d5f627accaf29dce7e6f8628cc1df SHA512 7c746848671d5de0b63f0284d2af87c12480fa1ae3e89eb10093ab5dfd42f926171f29bd8bcc19fe173fc58f7eff7276da4639d580836f0d112dc5e85000dc55

diff --git a/dev-python/bpython/bpython-0.19.ebuild b/dev-python/bpython/bpython-0.19.ebuild
new file mode 100644 (file)
index 0000000..fa686ec
--- /dev/null
+++ b/dev-python/bpython/bpython-0.19.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
+HOMEPAGE="https://www.bpython-interpreter.org/ https://github.com/bpython/bpython https://pypi.org/project/bpython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+       >=dev-python/curtsies-0.2.11[${PYTHON_USEDEP}]
+       dev-python/greenlet[${PYTHON_USEDEP}]
+       dev-python/jedi[${PYTHON_USEDEP}]
+       dev-python/pygments[${PYTHON_USEDEP}]
+       dev-python/requests[${PYTHON_USEDEP}]
+       >=dev-python/six-1.5[${PYTHON_USEDEP}]
+       dev-python/urwid[${PYTHON_USEDEP}]
+       dev-python/watchdog[${PYTHON_USEDEP}]
+       "
+DEPEND="${RDEPEND}
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+DOCS=( AUTHORS CHANGELOG sample.theme light.theme )
+
+# Req'd for clean build by each impl
+DISTUTILS_IN_SOURCE_BUILD=1
+
+RESTRICT="test" #659110
+
+python_compile_all() {
+       if use doc; then
+               sphinx-build -b html -c doc/sphinx/source/ \
+                       doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
+       fi
+}
+
+python_test() {
+       pushd build/lib > /dev/null
+       "${PYTHON}" -m unittest discover || die
+       popd > /dev/null
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
+       distutils-r1_python_install_all
+}