app-admin/ansible: fix missing dep on pexpect

Fixes: https://bugs.gentoo.org/693972
Package-Manager: Portage-2.3.69, Repoman-2.3.17
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

diff --git a/app-admin/ansible/ansible-2.7.13-r1.ebuild b/app-admin/ansible/ansible-2.7.13-r1.ebuild
new file mode 100644 (file)
index 0000000..401feb0
--- /dev/null
+++ b/app-admin/ansible/ansible-2.7.13-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Model-driven deployment, config management, and command execution framework"
+HOMEPAGE="https://ansible.com/"
+SRC_URI="https://releases.ansible.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~x64-macos"
+IUSE="doc test"
+
+RDEPEND="
+       dev-python/paramiko[${PYTHON_USEDEP}]
+       dev-python/jinja[${PYTHON_USEDEP}]
+       dev-python/pyyaml[${PYTHON_USEDEP}]
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       dev-python/cryptography[${PYTHON_USEDEP}]
+       dev-python/httplib2[${PYTHON_USEDEP}]
+       dev-python/six[${PYTHON_USEDEP}]
+       dev-python/netaddr[${PYTHON_USEDEP}]
+       dev-python/pexpect[${PYTHON_USEDEP}]
+       net-misc/sshpass
+       virtual/ssh
+"
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/packaging-16.6[${PYTHON_USEDEP}]
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? (
+               ${RDEPEND}
+               dev-python/nose[${PYTHON_USEDEP}]
+               >=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+               dev-python/passlib[${PYTHON_USEDEP}]
+               dev-python/coverage[${PYTHON_USEDEP}]
+               dev-python/unittest2[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )"
+
+# not included in release tarball
+RESTRICT="test"
+
+python_compile_all() {
+       if use doc; then
+               cd docs/docsite || die
+               export CPUS=4
+               emake -f Makefile.sphinx html
+       fi
+}
+
+python_test() {
+       nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/docsite/_build/html/. )
+       distutils-r1_python_install_all
+
+       doman docs/man/man1/*.1
+       dodoc -r examples
+}

diff --git a/app-admin/ansible/ansible-2.8.4-r1.ebuild b/app-admin/ansible/ansible-2.8.4-r1.ebuild
new file mode 100644 (file)
index 0000000..b078e69
--- /dev/null
+++ b/app-admin/ansible/ansible-2.8.4-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Model-driven deployment, config management, and command execution framework"
+HOMEPAGE="https://ansible.com/"
+SRC_URI="https://releases.ansible.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~x64-macos"
+IUSE="doc test"
+RESTRICT="test"
+
+RDEPEND="
+       dev-python/paramiko[${PYTHON_USEDEP}]
+       dev-python/jinja[${PYTHON_USEDEP}]
+       dev-python/pyyaml[${PYTHON_USEDEP}]
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       dev-python/cryptography[${PYTHON_USEDEP}]
+       dev-python/httplib2[${PYTHON_USEDEP}]
+       dev-python/six[${PYTHON_USEDEP}]
+       dev-python/netaddr[${PYTHON_USEDEP}]
+       dev-python/pexpect[${PYTHON_USEDEP}]
+       net-misc/sshpass
+       virtual/ssh
+"
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/packaging-16.6[${PYTHON_USEDEP}]
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/sphinx-notfound-page[${PYTHON_USEDEP}]
+       )
+       test? (
+               ${RDEPEND}
+               dev-python/nose[${PYTHON_USEDEP}]
+               >=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+               dev-python/passlib[${PYTHON_USEDEP}]
+               dev-python/coverage[${PYTHON_USEDEP}]
+               dev-python/unittest2[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )"
+
+python_compile_all() {
+       if use doc; then
+               cd docs/docsite || die
+               export CPUS=4
+               emake -f Makefile.sphinx html
+       fi
+}
+
+python_prepare_all() {
+       rm -fv MANIFEST.in || die
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/docsite/_build/html/. )
+       distutils-r1_python_install_all
+
+       dodoc -r examples
+}

diff --git a/app-admin/ansible/ansible-9999.ebuild b/app-admin/ansible/ansible-9999.ebuild
index c35e90491f7ce859d0bdd4510a0f78d4c9d41868..64bfd80376028877d1a1474d22a3ebcb2564314e 100644 (file)
--- a/app-admin/ansible/ansible-9999.ebuild
+++ b/app-admin/ansible/ansible-9999.ebuild
@@ -27,6 +27,7 @@ RDEPEND="
        dev-python/httplib2[${PYTHON_USEDEP}]
        dev-python/six[${PYTHON_USEDEP}]
        dev-python/netaddr[${PYTHON_USEDEP}]
+       dev-python/pexpect[${PYTHON_USEDEP}]
        net-misc/sshpass
        virtual/ssh
 "