media-sound/jack-{1.9.13-r1,9999}: bug #699124

Closes: https://bugs.gentoo.org/699124
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

diff --git a/media-sound/jack2/jack2-1.9.13-r1.ebuild b/media-sound/jack2/jack2-1.9.13-r1.ebuild
new file mode 100644 (file)
index 0000000..8232a61
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.13-r1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_5 python3_6 python3_7 )
+PYTHON_REQ_USE="threads(+)"
+inherit python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="http://jackaudio.org/"
+
+if [[ "${PV}" = "9999" ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+else
+       MY_PV="${PV/_rc/-RC}"
+       MY_P="${PN}-${MY_PV}"
+       S="${WORKDIR}/${MY_P}"
+       SRC_URI="https://github.com/jackaudio/jack2/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+       KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
+
+REQUIRED_USE="
+       ${PYTHON_REQUIRED_USE}
+       || ( classic dbus )"
+
+CDEPEND="${PYTHON_DEPS}
+       media-libs/libsamplerate
+       media-libs/libsndfile
+       sys-libs/readline:0=
+       alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+       dbus? (
+               dev-libs/expat[${MULTILIB_USEDEP}]
+               sys-apps/dbus[${MULTILIB_USEDEP}]
+       )
+       ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
+       metadata? ( sys-libs/db )
+       opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+DEPEND="${CDEPEND}
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen )"
+RDEPEND="${CDEPEND}
+       dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+       pam? ( sys-auth/realtime-base )
+       !media-sound/jack-audio-connection-kit:0"
+
+DOCS=( ChangeLog.rst README.rst README_NETJACK2 )
+
+src_prepare() {
+       default
+       multilib_copy_sources
+}
+
+multilib_src_configure() {
+       local mywafconfargs=(
+               --htmldir=/usr/share/doc/${PF}/html
+               $(usex dbus --dbus "")
+               $(usex classic --classic "")
+               --alsa=$(usex alsa yes no)
+               --celt=no
+               --db=$(usex metadata yes no)
+               --doxygen=$(multilib_native_usex doc yes no)
+               --firewire=$(usex ieee1394 yes no)
+               --iio=no
+               --opus=$(usex opus yes no)
+               --portaudio=no
+               --readline=$(multilib_native_usex readline yes no)
+               --samplerate=$(multilib_native_usex libsamplerate yes no)
+               --sndfile=$(multilib_native_usex sndfile yes no)
+               --winmme=no
+       )
+
+       waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+       WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+}
+
+multilib_src_install() {
+       WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+       python_fix_shebang "${ED}"
+}

diff --git a/media-sound/jack2/jack2-9999.ebuild b/media-sound/jack2/jack2-9999.ebuild
index 45dd8b8c38a8c5d189ee338599864169f45017ac..4e310216955b12fecf724ebf681c1b4bfcc07f65 100644 (file)
--- a/media-sound/jack2/jack2-9999.ebuild
+++ b/media-sound/jack2/jack2-9999.ebuild
@@ -23,7 +23,7 @@ fi
 
 LICENSE="GPL-2"
 SLOT="2"
-IUSE="alsa +classic dbus doc ieee1394 libsamplerate opus pam readline sndfile"
+IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}
        || ( classic dbus )"
@@ -38,6 +38,7 @@ COMMON_DEPEND="${PYTHON_DEPS}
                sys-apps/dbus[${MULTILIB_USEDEP}]
        )
        ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
+       metadata? ( sys-libs/db )
        opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
 DEPEND="${COMMON_DEPEND}
        virtual/pkgconfig
@@ -61,6 +62,7 @@ multilib_src_configure() {
                $(usex classic --classic "")
                --alsa=$(usex alsa yes no)
                --celt=no
+               --db=$(usex metadata yes no)
                --doxygen=$(multilib_native_usex doc yes no)
                --firewire=$(usex ieee1394 yes no)
                --iio=no

diff --git a/media-sound/jack2/metadata.xml b/media-sound/jack2/metadata.xml
index 7956a5fa461855a3f3182c40d7dbc6b8ac7ebd2d..61e6667c2b4ee04bdc318300e6f3f356aafd43ec 100644 (file)
--- a/media-sound/jack2/metadata.xml
+++ b/media-sound/jack2/metadata.xml
@@ -10,6 +10,7 @@
        </upstream>
        <use>
                <flag name="classic">Enable building of jackd</flag>
+               <flag name="metadata">Enable metadata API</flag>
                <flag name="pam">Add basic realtime configuration via <pkg>sys-auth/realtime-base</pkg></flag>
        </use>
 </pkgmetadata>