dev-libs/libical: 3.0.7 version bump

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/dev-libs/libical/Manifest b/dev-libs/libical/Manifest
index 370e00b64ca556af684c24e15b4fca7cda21f538..80ec0cbab3bff6c2faed8ffa2cfe210db4c915a6 100644 (file)
--- a/dev-libs/libical/Manifest
+++ b/dev-libs/libical/Manifest
@@ -1,2 +1,3 @@
 DIST libical-3.0.5.tar.gz 881800 BLAKE2B 64f95950cc6f128c9ea475129e54d9c58b26d9866f8183762d34c996934a1b2bcc528c47442357a12fb6444831caa8f39772a6810d81f8c0b6596fd724f0de6c SHA512 9bf24b535864f66ea0b8d52d902d15fbfd20efbc480b5188ecd1b3d4aafdba063219763f99a8c30413964f7a024c7a902bade6bc40224bc59a438e672f65d656
 DIST libical-3.0.6.tar.gz 879939 BLAKE2B 365e16cd7011df7e9e8bcf011035aeeb904a511c5a0ff76cde5b559a7c56049646108d1c2b499cd044e2784aef7bb1370ee3dbf88c24b745a349a0ee7c312157 SHA512 d1a3397071c2989983893e3bbaeb088f7cb9a3639dca39709e9422c334dd1e9a869bba9292a250f83eb2a5b6727bd91b73c8e420bd1814422d97aff9fc6b26fc
+DIST libical-3.0.7.tar.gz 881352 BLAKE2B ad256833a69ba2e76301b1d9f732ac22c3d5a0030bb81e2d8ef57471338fc583cf1dd21cccb1301d3fcfbe1905a42bebec7c811e90cc8b10faa6e773fc1366fc SHA512 4e1df3fad9c9df795da441243471d05168287519b6155b148b5aa28092ecac687626fa92713b280864a41f6ffc0c7fb43d2770fb1821396cb838e96e76d8d9d8

diff --git a/dev-libs/libical/libical-3.0.7.ebuild b/dev-libs/libical/libical-3.0.7.ebuild
new file mode 100644 (file)
index 0000000..0df1bdb
--- /dev/null
+++ b/dev-libs/libical/libical-3.0.7.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+VALA_USE_DEPEND="vapigen"
+inherit cmake-utils python-any-r1 vala
+
+DESCRIPTION="An implementation of basic iCAL protocols"
+HOMEPAGE="https://github.com/libical/libical"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="berkdb doc examples introspection static-libs test vala"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vala? ( introspection )"
+
+BDEPEND="
+       dev-lang/perl
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen )
+       introspection? ( dev-libs/gobject-introspection )
+       test? ( ${PYTHON_DEPS} )
+       vala? ( $(vala_depend) )
+"
+COMMON_DEPEND="
+       dev-libs/icu:=
+       berkdb? ( sys-libs/db:= )
+       introspection? ( dev-libs/glib:2 )
+"
+DEPEND="${COMMON_DEPEND}
+       introspection? ( dev-libs/libxml2:2 )
+"
+RDEPEND="${COMMON_DEPEND}
+       sys-libs/timezone-data
+"
+
+DOCS=(
+       AUTHORS ReadMe.txt ReleaseNotes.txt TEST THANKS TODO
+       doc/{AddingOrModifyingComponents,UsingLibical}.txt
+)
+
+PATCHES=(
+       "${FILESDIR}/${PN}-3.0.4-tests.patch"
+       "${FILESDIR}/${PN}-3.0.5-pkgconfig-libdir.patch"
+)
+
+pkg_setup() {
+       use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+       cmake-utils_src_prepare
+       use examples || cmake_comment_add_subdirectory examples
+       use vala && vala_src_prepare
+}
+
+src_configure() {
+       local mycmakeargs=(
+               $(cmake-utils_use_find_package berkdb BDB)
+               -DICAL_BUILD_DOCS=$(usex doc)
+               -DICAL_GLIB=$(usex introspection)
+               -DGOBJECT_INTROSPECTION=$(usex introspection)
+               -DSHARED_ONLY=$(usex !static-libs)
+               -DLIBICAL_BUILD_TESTING=$(usex test)
+               -DICAL_GLIB_VAPI=$(usex vala)
+       )
+       if use vala; then
+               mycmakeargs+=(
+                       -DVALAC="${VALAC}"
+                       -DVAPIGEN="${VAPIGEN}"
+               )
+       fi
+       cmake-utils_src_configure
+}
+
+src_compile() {
+       cmake-utils_src_compile
+       use doc && cmake-utils_src_compile docs
+}
+
+src_test() {
+       local myctestargs=(
+               -E "(icalrecurtest|icalrecurtest-r)" # bug 660282
+       )
+
+       cmake-utils_src_test
+}
+
+src_install() {
+       use doc && HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
+
+       cmake-utils_src_install
+
+       if use examples; then
+               rm examples/CMakeLists.txt || die
+               dodoc -r examples
+       fi
+}