dev-util/conan: update to 1.14.1

Closes: https://bugs.gentoo.org/717512
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/15464
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

diff --git a/dev-util/conan/Manifest b/dev-util/conan/Manifest
index 9b5c7e350bc827cd489446813ad9e8fcf1e474c7..3d3c0a1e9d4549997c46eaa2c556b2a7399ea560 100644 (file)
--- a/dev-util/conan/Manifest
+++ b/dev-util/conan/Manifest
@@ -1 +1,2 @@
 DIST conan-1.23.0.tar.gz 1024905 BLAKE2B cfa3e130be13ee175b1dc167b6d61666eddaf588b5954d9889c2d167806e8fb115290257ca839f6de407c87079472dba912b730e01a232d70375f2fe63ce7c28 SHA512 fa2b1b726e29ef553774267b50b0ace4f39a30bdf0a6d0e051576bc9b0e6cd1ed6cb166101c446d15734ebef9e89e17a101c10c0ead91c15de5aa1ebb102d0a8
+DIST conan-1.24.1.tar.gz 1043698 BLAKE2B 33e5aaa975a9819d0808c90ad97260b00aab6f4ae8ba6feb7d2c53622f0e72b87cc469c7c21994e2c228819bd364dc9b20822134c10665978bf996b653c014b9 SHA512 ab6e15c4291862d9d68661682ec9da8c126193ddb00b800e3d8f9dba07a516db307d22e590324ae3f059e39e897bc6bf590e53cc82d69431ce287031be7fe820

diff --git a/dev-util/conan/conan-1.24.1.ebuild b/dev-util/conan/conan-1.24.1.ebuild
new file mode 100644 (file)
index 0000000..5cedb0a
--- /dev/null
+++ b/dev-util/conan/conan-1.24.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Distributed C/C++ package manager"
+HOMEPAGE="https://conan.io/"
+SRC_URI="https://github.com/conan-io/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+# overly strict requirements?
+# https://github.com/conan-io/conan/blob/develop/conans/requirements.txt
+# https://github.com/conan-io/conan/blob/develop/conans/requirements_server.txt
+RDEPEND="
+       >=dev-python/bottle-0.12.8[${PYTHON_USEDEP}]
+       >=dev-python/colorama-0.3.3[${PYTHON_USEDEP}]
+       >=dev-python/deprecation-2.0[${PYTHON_USEDEP}]
+       >=dev-python/distro-1.0.2[${PYTHON_USEDEP}]
+       >=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+       >=dev-python/future-0.16.0[${PYTHON_USEDEP}]
+       >=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+       >=dev-python/node-semver-0.6.1[${PYTHON_USEDEP}]
+       >=dev-python/patch-ng-1.17.4[${PYTHON_USEDEP}]
+       >=dev-python/pluginbase-0.5[${PYTHON_USEDEP}]
+       >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+       >=dev-python/pyjwt-1.4[${PYTHON_USEDEP}]
+       >=dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
+       >=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+       >=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+       >=dev-python/tqdm-4.28.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests nose
+DEPEND+="
+       test? (
+               dev-lang/go
+               dev-vcs/git
+               dev-vcs/subversion
+               >=dev-python/mock-1.3.0[${PYTHON_USEDEP}]
+               >=dev-python/nose-1.3.7[${PYTHON_USEDEP}]
+               >=dev-python/parameterized-0.6.3[${PYTHON_USEDEP}]
+               >=dev-python/webtest-2.0.18[${PYTHON_USEDEP}]
+               dev-util/cmake
+       )
+"
+
+src_prepare() {
+       default
+       # Fix strict dependencies
+       sed -i \
+               -e "s:six>=1.10.0,<1.14.0:six>=1.12.0:g" \
+               -e "s:node-semver==0.6.1:node-semver>=0.6.1:g" \
+               conans/requirements.txt || die
+}
+
+python_test() {
+       nosetests -v conans.test \
+               -e test_ftp.* -e modify_values_test.* -e test_pkg_config_path.* \
+               -e rpath_optin_test -e test_variables -e system_package_tool_installed_test \
+               -e virtualbuildenv_test -e scm_test -e test_git_shallow -e tools_test \
+               -e test_environment_nested -e devflow_test -e shared_chain_test \
+               -e virtualenv_test \
+               -A "not rest_api and not local_bottle" || die
+}