gnome-extra/gnome-user-share: bump to 3.34.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/gnome-extra/gnome-user-share/Manifest b/gnome-extra/gnome-user-share/Manifest
index 155f60321c9bc5540931bbba42ba1daa5f482c66..83884ce1b3ba16775e33d14d94c9f1236341f151 100644 (file)
--- a/gnome-extra/gnome-user-share/Manifest
+++ b/gnome-extra/gnome-user-share/Manifest
@@ -1 +1,2 @@
 DIST gnome-user-share-3.32.0.1.tar.xz 439696 BLAKE2B 278e46adfdb2a24a2b9d8d76e38bb9a6cb1b5ee85c820fbc38aa1ebbed2481537dc8686dccef3d213c0c83bb236f1431a9706b3d6cceace78172d93798534d76 SHA512 d644aaf0c0b593188936505391b1927d883234ffa5acd6d04675575fc68409512b416d87ca6d0a7960187b433a874f2da6ec2d304eccbab8846446f89df8297e
+DIST gnome-user-share-3.34.0.tar.xz 109560 BLAKE2B 02d0788ff6b4b1a87ebd1d5dee2a853ce0418a553aa2be262227f0b8984ed8bcf84bec774b43952425e96d8b14f4100fd42e0dbec02cc91e67e0881f9155005d SHA512 7aa5f0cad4b96af41b5e4b4a125cb7a9d7a7c27ba10cdf7c4acd2aaffe5bfb3494c9319b997e547c996017827383f7653905c3e0af67c65922635b7ac49803f5

diff --git a/gnome-extra/gnome-user-share/gnome-user-share-3.34.0.ebuild b/gnome-extra/gnome-user-share/gnome-user-share-3.34.0.ebuild
new file mode 100644 (file)
index 0000000..fac4406
--- /dev/null
+++ b/gnome-extra/gnome-user-share/gnome-user-share-3.34.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson multilib systemd xdg
+
+DESCRIPTION="Personal file sharing for the GNOME desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-user-share"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+# FIXME: could libnotify be made optional ?
+# FIXME: selinux automagic support
+RDEPEND="
+       >=dev-libs/glib-2.58:2
+       >=x11-libs/gtk+-3:3
+       >=gnome-base/nautilus-3.27.90
+       >=www-apache/mod_dnssd-0.6
+       >=www-servers/apache-2.2[apache2_modules_dav,apache2_modules_dav_fs,apache2_modules_authn_file,apache2_modules_auth_digest,apache2_modules_authz_groupfile]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       >=sys-devel/gettext-0.19.8
+       virtual/pkgconfig
+"
+
+PATCHES=(
+       # Upstream forces to use prefork because of Fedora defaults, but
+       # that is problematic for us (bug #551012)
+       # https://bugzilla.gnome.org/show_bug.cgi?id=750525#c2
+       "${FILESDIR}"/${PN}-3.18.1-no-prefork.patch
+)
+
+src_configure() {
+       local emesonargs=(
+               -Dsystemduserunitdir="$(systemd_get_userunitdir)"
+               -Dhttpd=apache2
+               -Dmodules_path=/usr/$(get_libdir)/apache2/modules/
+       )
+       meson_src_configure
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+       gnome2_schemas_update
+}
+
+pkg_postrm() {
+       xdg_pkg_postrm
+       gnome2_schemas_update
+}