dev-python/clang-python: Add 9.0 branch live ebuild

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/dev-python/clang-python/clang-python-9.0.9999.ebuild b/dev-python/clang-python/clang-python-9.0.9999.ebuild
new file mode 100644 (file)
index 0000000..6bf0e1c
--- /dev/null
+++ b/dev-python/clang-python/clang-python-9.0.9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+inherit git-r3 python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+SRC_URI=""
+EGIT_REPO_URI="https://git.llvm.org/git/clang.git
+       https://github.com/llvm-mirror/clang.git"
+EGIT_BRANCH="release_90"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+       >=sys-devel/clang-${PV}:*
+       !sys-devel/llvm:0[clang(-),python(-)]
+       !sys-devel/clang:0[python(-)]
+       ${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${P}/bindings/python
+
+src_unpack() {
+       git-r3_fetch
+       git-r3_checkout '' '' '' bindings/python
+}
+
+python_test() {
+       "${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+       python_foreach_impl python_test
+}
+
+src_install() {
+       python_foreach_impl python_domodule clang
+}