Added a patch to make the skip_plugin method work also on stopping of vdr.

Package-Manager: portage-2.1.1_pre1-r1

diff --git a/media-tv/gentoo-vdr-scripts/ChangeLog b/media-tv/gentoo-vdr-scripts/ChangeLog
index 70ecac008b448b042cb4a423e90c81e0380ce53e..d75ddfc0309142a82ab7d0b726456313201e1a5b 100644 (file)
--- a/media-tv/gentoo-vdr-scripts/ChangeLog
+++ b/media-tv/gentoo-vdr-scripts/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-tv/gentoo-vdr-scripts
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.56 2006/06/16 13:18:27 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.57 2006/06/19 11:18:41 zzam Exp $
+
+*gentoo-vdr-scripts-0.3.5-r1 (19 Jun 2006)
+
+  19 Jun 2006; Matthias Schwarzott <zzam@gentoo.org>
+  +files/gentoo-vdr-scripts-0.3.5-skip-plugin.diff,
+  -gentoo-vdr-scripts-0.3.5.ebuild, +gentoo-vdr-scripts-0.3.5-r1.ebuild:
+  Added a patch to make the skip_plugin method work also on stopping of vdr.
 
 *gentoo-vdr-scripts-0.3.5 (16 Jun 2006)
 

diff --git a/media-tv/gentoo-vdr-scripts/files/digest-gentoo-vdr-scripts-0.3.5-r1 b/media-tv/gentoo-vdr-scripts/files/digest-gentoo-vdr-scripts-0.3.5-r1
new file mode 100644 (file)
index 0000000..4b4129a
--- /dev/null
+++ b/media-tv/gentoo-vdr-scripts/files/digest-gentoo-vdr-scripts-0.3.5-r1
@@ -0,0 +1,3 @@
+MD5 ab528a3a017c3cdd4ed5cc28b18f5f6b gentoo-vdr-scripts-0.3.5.tar.bz2 22643
+RMD160 5782d55d2b62c11cd74193dd09588e4c9ca27b9a gentoo-vdr-scripts-0.3.5.tar.bz2 22643
+SHA256 c099dc98b7979b7dc036268adc8f90082f180d9d7f225bdbdfce35fa8376b83d gentoo-vdr-scripts-0.3.5.tar.bz2 22643

diff --git a/media-tv/gentoo-vdr-scripts/files/gentoo-vdr-scripts-0.3.5-skip-plugin.diff b/media-tv/gentoo-vdr-scripts/files/gentoo-vdr-scripts-0.3.5-skip-plugin.diff
new file mode 100644 (file)
index 0000000..9da59dc
--- /dev/null
+++ b/media-tv/gentoo-vdr-scripts/files/gentoo-vdr-scripts-0.3.5-skip-plugin.diff
@@ -0,0 +1,21 @@
+--- gentoo-vdr-scripts-0.3.5/usr/share/vdr/inc/plugin-functions.sh     2006-06-16 15:15:06.000000000 +0200
++++ gentoo-vdr-scripts-0.3.5/usr/share/vdr/inc/plugin-functions.sh     2006-06-19 13:10:16.000000000 +0200
+@@ -36,6 +36,7 @@
+ }
+ 
+ check_plugin() {
++      SKIP_PLUGIN=0
+       local PLUGIN="${1}"
+       local plugin_file="${plugin_dir}/libvdr-${PLUGIN}.so.${APIVERSION}"
+ 
+--- gentoo-vdr-scripts-0.3.5/usr/share/vdr/rcscript/pre-start-95-plugins.sh    2006-06-16 15:15:06.000000000 +0200
++++ gentoo-vdr-scripts-0.3.5/usr/share/vdr/rcscript/pre-start-95-plugins.sh    2006-06-19 13:10:16.000000000 +0200
+@@ -5,8 +5,6 @@
+ addon_main() {
+       local PLUGIN
+       for PLUGIN in ${PLUGINS}; do
+-              SKIP_PLUGIN=0
+-
+               init_plugin_params ${PLUGIN}
+ 
+               load_plugin ${PLUGIN} plugin_pre_vdr_start

diff --git a/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.3.5-r1.ebuild b/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.3.5-r1.ebuild
new file mode 100644 (file)
index 0000000..2612a35
--- /dev/null
+++ b/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.3.5-r1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-0.3.5-r1.ebuild,v 1.1 2006/06/19 11:18:41 zzam Exp $
+
+inherit eutils
+
+IUSE="nvram"
+
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+DESCRIPTION="scripts necessary for use of vdr as a set-top-box"
+HOMEPAGE="http://www.gentoo.org/"
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="nvram? ( x86? ( sys-power/nvram-wakeup ) )
+               app-admin/sudo"
+
+VDR_HOME=/var/vdr
+
+pkg_setup() {
+       enewgroup vdr
+       enewuser vdr -1 /bin/bash ${VDR_HOME} vdr,video,audio,cdrom
+}
+
+src_unpack() {
+       unpack ${A}
+
+       epatch ${FILESDIR}/${P}-skip-plugin.diff
+}
+
+src_install() {
+       local myopts=""
+       if use nvram; then
+               if use x86; then
+                       myopts="${myopts} NVRAM=1"
+               else
+                       ewarn "nvram-wakeup is not available on this architecture."
+               fi
+       fi
+
+       make install DESTDIR="${D}" ${myopts} || die "make install failed"
+       dodoc README TODO ChangeLog
+
+
+       keepdir /var/vdr/shutdown-data
+       keepdir /var/vdr/merged-config-files
+       keepdir /var/vdr/dvd-images
+
+       local MAKE_VIDEO_DIR=1
+       local testd
+       for testd in video0 video00 video.0 video.00; do
+               [[ -d ${ROOT}/var/vdr/${testd} ]] && MAKE_VIDEO_DIR=0
+       done
+       if [[ ${MAKE_VIDEO_DIR} == 1 ]]; then
+               keepdir /var/vdr/video
+       fi
+
+       chown vdr:vdr -R ${D}/var/vdr
+}
+
+pkg_preinst() {
+       local owner
+       local d
+       for d in /etc/vdr /var/vdr; do
+               if [[ -d ${d} ]]; then
+                       owner=$(stat ${d} -c "%U")
+                       if [[ ${owner} != vdr ]]; then
+                               einfo "Changing ownership of ${d}"
+                               chown -R vdr:vdr ${d}
+                       fi
+               fi
+       done
+}
+
+VDRSUDOENTRY="vdr ALL=NOPASSWD:/usr/lib/vdr/bin/vdrshutdown-really.sh"
+
+pkg_postinst() {
+       einfo
+       einfo "To make shutdown work add this line to /etc/sudoers"
+       einfo "    $VDRSUDOENTRY"
+       einfo
+       einfo "or execute this command:"
+       einfo "    emerge --config gentoo-vdr-scripts"
+       einfo
+       ewarn "The default video directory was moved to /var/vdr/video"
+       ewarn "If you have your video directory anywhere else, then"
+       ewarn "change the setting VIDEO in the file /etc/conf.d/vdr."
+       ewarn
+       if use x86 && use !nvram; then
+               ewarn "nvram wakeup is now optional."
+               ewarn "To make use of it enable the use flag nvram."
+       fi
+}
+
+pkg_config() {
+       if grep -q /usr/lib/vdr/bin/vdrshutdown-really.sh ${ROOT}/etc/sudoers; then
+               einfo "sudoers-entry for vdr already in place."
+       else
+               einfo "Adding this line to /etc/sudoers:"
+               einfo "+  ${VDRSUDOENTRY}"
+
+               cd ${T}
+               cat >sudoedit-vdr.sh <<-SUDOEDITOR
+                       #!/bin/bash
+                       echo "" >> \${1}
+                       echo "${VDRSUDOENTRY}" >> \${1}
+               SUDOEDITOR
+               chmod a+x sudoedit-vdr.sh
+
+               VISUAL=${T}/sudoedit-vdr.sh visudo -f ${ROOT}/etc/sudoers || die "visudo failed"
+
+               einfo "Edited /etc/sudoers"
+       fi
+}
+