dev-libs/libf2c: Version Bump

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=546272

Package-Manager: portage-2.2.20.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

diff --git a/dev-libs/libf2c/Manifest b/dev-libs/libf2c/Manifest
index a9c14b85c08ef43bb751feade1436ac22ddeb9a8..a20073699c27691b0d70e4e496c631375d5bb61f 100644 (file)
--- a/dev-libs/libf2c/Manifest
+++ b/dev-libs/libf2c/Manifest
@@ -1 +1,2 @@
 DIST libf2c-20110801.zip 128845 SHA256 f13c01421e9668dc86c78159d87c2f802dd1f8e62037834285c7ab77200d97d5 SHA512 7a7b7b02ca2b11456aa0deba5094aebc1e9f7070d1742ad76450ec79de7eed967fbd7446524b66c52295ed911471d2dc396d171569b5d37079bdca8220fd2fb6 WHIRLPOOL 7bc8fa6c016dbb860863b39939f27f99156de017a2847764698bc0b5bbf21ff183e783991d6c5200ddba1b636e9a8bb93d560c00344db94b4e9a7b254abdafde
+DIST libf2c-20130927.zip 129082 SHA256 5dff29c58b428fa00cd36b1220e2d71b9882a658fdec1aa094fb7e6e482d6765 SHA512 1a12093dec3c250f4775eebd06f1a9144fdb956ea3162202fb67569fdd956ac5591bc563a0726ca65ea10d465efaac1c1d8024d63bc4a4b5c88bf46242607c8a WHIRLPOOL 0b46ae7e797fe80534a4576508920dca0122fab475b8c3034257b3f3c1bef68d02f981d676565e0e6f82a3ae112b482fb702265dd025202b2359f432dc66a939

diff --git a/dev-libs/libf2c/libf2c-20130927.ebuild b/dev-libs/libf2c/libf2c-20130927.ebuild
new file mode 100644 (file)
index 0000000..fc568fd
--- /dev/null
+++ b/dev-libs/libf2c/libf2c-20130927.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="Library that converts FORTRAN to C source"
+HOMEPAGE="http://www.netlib.org/f2c/"
+SRC_URI="${HOMEPAGE}/${PN}.zip -> ${P}.zip"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+       app-arch/unzip"
+
+S="${WORKDIR}"
+
+src_prepare() {
+       epatch \
+               "${FILESDIR}"/20051004-add-ofiles-dep.patch \
+               "${FILESDIR}"/20090407-link-shared-libf2c-correctly.patch \
+               "${FILESDIR}"/${PN}-20110801-main.patch\
+               "${FILESDIR}"/${PN}-20110801-64bit-long.patch \
+               "${FILESDIR}"/${PN}-20110801-format-security.patch
+       sed -i -e "s/ld /$(tc-getLD) /" makefile.u || die
+}
+
+src_compile() {
+       emake \
+               -f makefile.u \
+               libf2c.so \
+               CFLAGS="${CFLAGS} -fPIC" \
+               CC="$(tc-getCC)"
+
+       # Clean up files so we can recompile without PIC for the static lib
+       if use static-libs; then
+               rm *.o || die "clean failed"
+               emake \
+                       -f makefile.u \
+                       all \
+                       CFLAGS="${CFLAGS}" \
+                       CC="$(tc-getCC)"
+       fi
+}
+
+src_install () {
+       dolib libf2c.so.2
+       dosym libf2c.so.2 /usr/$(get_libdir)/libf2c.so
+       use static-libs && dolib.a libf2c.a
+       doheader f2c.h
+       dodoc README Notice
+}