dev-util/glade: bump to 3.22.2

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/dev-util/glade/Manifest b/dev-util/glade/Manifest
index 902fe279ab554492eb2115dd12cd1638ef2d1f35..ac0b819613d3cbf02fb907a84124d1b68837f51d 100644 (file)
--- a/dev-util/glade/Manifest
+++ b/dev-util/glade/Manifest
@@ -1 +1,2 @@
 DIST glade-3.22.1.tar.xz 3592952 BLAKE2B 53f769198a093ff5d4dc98bb4ea98c6e5195933caf24247a99db980312ae3398fca3abbd640d08c02e8fb5f8647ee3e4b18e65073b1500e9017ee0586993a331 SHA512 e1bdc49b89bc5010c0abf6357dbae05c921182655b2ee5a4b161af6adfd596cfbcd495c9851ba956abbf3d6156616a6c0e94640cd72cee11551ca388674ac908
+DIST glade-3.22.2.tar.xz 3550008 BLAKE2B e1217e221b36938937c57ae465a3707eeadc52bc9127b3af2fb6514e572676e3e284811d5332876dce110fd321e2bb33b9ac8b0afbd97dd747725eb73309dc15 SHA512 cb82684423ae055bc8e84a8705529ecdc72957563f444633c2c5c24a922130de84c212537323b6ed259f0e29349b52dff608822610b87babb8fc3cb468a5f4b0

diff --git a/dev-util/glade/glade-3.22.2.ebuild b/dev-util/glade/glade-3.22.2.ebuild
new file mode 100644 (file)
index 0000000..83c8db8
--- /dev/null
+++ b/dev-util/glade/glade-3.22.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome2 python-single-r1 virtualx
+
+DESCRIPTION="A user interface designer for GTK+ and GNOME"
+HOMEPAGE="https://glade.gnome.org/"
+
+LICENSE="GPL-2+ FDL-1.1+"
+SLOT="3.10/6" # subslot = suffix of libgladeui-2.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
+
+IUSE="debug +introspection python webkit"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       dev-libs/atk[introspection?]
+       >=dev-libs/glib-2.53.2:2
+       >=dev-libs/libxml2-2.4.0:2
+       x11-libs/cairo:=
+       x11-libs/gdk-pixbuf:2[introspection?]
+       >=x11-libs/gtk+-3.20.0:3[introspection?]
+       x11-libs/pango[introspection?]
+       introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+       python? (
+               ${PYTHON_DEPS}
+               x11-libs/gtk+:3[introspection]
+               $(python_gen_cond_dep '
+                       >=dev-python/pygobject-3.8:3[${PYTHON_MULTI_USEDEP}]
+               ')
+       )
+       webkit? ( >=net-libs/webkit-gtk-2.12.0:4 )
+"
+DEPEND="${RDEPEND}
+       app-text/docbook-xml-dtd:4.1.2
+       dev-libs/libxslt
+       >=dev-util/gtk-doc-am-1.13
+       >=dev-util/intltool-0.41.0
+       dev-util/itstool
+       virtual/pkgconfig
+"
+# eautoreconf requires:
+#      app-text/yelp-tools
+#      dev-libs/gobject-introspection-common
+#      gnome-base/gnome-common
+
+RESTRICT="test" # https://gitlab.gnome.org/GNOME/glade/issues/333
+
+PATCHES=(
+       # To avoid file collison with other slots, rename help module.
+       # Prevent the UI from loading glade:3's gladeui devhelp documentation.
+       "${FILESDIR}"/${PN}-3.14.1-doc-version.patch
+)
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       gnome2_src_configure \
+               --disable-static \
+               --enable-gladeui \
+               --enable-libtool-lock \
+               $(usex debug --enable-debug ' ') \
+               $(use_enable introspection) \
+               $(use_enable python) \
+               $(use_enable webkit webkit2gtk)
+}
+
+src_test() {
+       virtx emake check
+}
+
+src_install() {
+       # modify name in .devhelp2 file to avoid shadowing with glade:3 docs
+       sed -e 's:name="gladeui":name="gladeui-2":' \
+               -i doc/html/gladeui.devhelp2 || die "sed of gladeui.devhelp2 failed"
+       gnome2_src_install
+}
+
+pkg_postinst() {
+       gnome2_pkg_postinst
+       if ! has_version dev-util/devhelp ; then
+               elog "You may want to install dev-util/devhelp for integration API"
+               elog "documentation support."
+       fi
+}