dev-libs/libgcrypt: eapi bump

Package-Manager: Portage-2.3.49, Repoman-2.3.10
Signed-off-by: Alon Bar-Lev <alonbl@gentoo.org>

diff --git a/dev-libs/libgcrypt/libgcrypt-1.8.3-r1.ebuild b/dev-libs/libgcrypt/libgcrypt-1.8.3-r1.ebuild
new file mode 100644 (file)
index 0000000..4f3b5d9
--- /dev/null
+++ b/dev-libs/libgcrypt/libgcrypt-1.8.3-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="General purpose crypto library based on the code used in GnuPG"
+HOMEPAGE="http://www.gnupg.org/"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1 MIT"
+SLOT="0/20" # subslot = soname major version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc o-flag-munging static-libs"
+
+RDEPEND=">=dev-libs/libgpg-error-1.25[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( virtual/texi2dvi )"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-1.6.1-uscore.patch
+       "${FILESDIR}"/${PN}-multilib-syspath.patch
+)
+
+MULTILIB_CHOST_TOOLS=(
+       /usr/bin/libgcrypt-config
+)
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+multilib_src_configure() {
+       if [[ ${CHOST} == *86*-solaris* ]] ; then
+               # ASM code uses GNU ELF syntax, divide in particular, we need to
+               # allow this via ASFLAGS, since we don't have a flag-o-matic
+               # function for that, we'll have to abuse cflags for this
+               append-cflags -Wa,--divide
+       fi
+       local myeconfargs=(
+               --disable-dependency-tracking
+               --enable-noexecstack
+               $(use_enable o-flag-munging O-flag-munging)
+               $(use_enable static-libs static)
+
+               # disabled due to various applications requiring privileges
+               # after libgcrypt drops them (bug #468616)
+               --without-capabilities
+
+               # http://trac.videolan.org/vlc/ticket/620
+               # causes bus-errors on sparc64-solaris
+               $([[ ${CHOST} == *86*-darwin* ]] && echo "--disable-asm")
+               $([[ ${CHOST} == sparcv9-*-solaris* ]] && echo "--disable-asm")
+
+               GPG_ERROR_CONFIG="${EROOT}/usr/bin/${CHOST}-gpg-error-config"
+       )
+       ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+       default
+       multilib_is_native_abi && use doc && VARTEXFONTS="${T}/fonts" emake -C doc gcrypt.pdf
+}
+
+multilib_src_install() {
+       emake DESTDIR="${D}" install
+       multilib_is_native_abi && use doc && dodoc doc/gcrypt.pdf
+}
+
+multilib_src_install_all() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}