dev-python/py-amqp: 2.5.2 bump

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

diff --git a/dev-python/py-amqp/Manifest b/dev-python/py-amqp/Manifest
index be00d6a220c690ee600e91f7ece0c02e4b77665e..e65db6fbd5b0bc7c6175d705b3d96c289f289523 100644 (file)
--- a/dev-python/py-amqp/Manifest
+++ b/dev-python/py-amqp/Manifest
@@ -1 +1,2 @@
 DIST amqp-2.5.0.tar.gz 117022 BLAKE2B d05df3699a73ee3cc9540599b7947b4ad9fc1d74194cfbea81787d85c0f83262d109c153669d746ccfb67a1ecb21755da4615043ebfa67c84c8f108ef61ecd3c SHA512 c0675b85bb4d8bdc7c303bb694153c86eb503fa3c4fe6b6c4dac6b1f3aac2fbfa75a4ec39ea8bbdedc297a6a3407a0a5b560885df761e667e3c0770f5979156b
+DIST amqp-2.5.2.tar.gz 117788 BLAKE2B 6a6990aca0a43a0c546198b999d0d3680d6c44908e144f81bd8266abac4d2d9b7ea4c65bbf969310f1236970ebe0ef5ed44cc558109ba1f680348e3ba2789e83 SHA512 c540ce39c06bb947e55b4afc56567d5fc5a82b65a2f7e2cc1f769f96da74f788d14e1e9c02852a259a4980c36a4524f07166686c0357f96219fd9f8612a6159a

diff --git a/dev-python/py-amqp/py-amqp-2.5.2.ebuild b/dev-python/py-amqp/py-amqp-2.5.2.ebuild
new file mode 100644 (file)
index 0000000..02877aa
--- /dev/null
+++ b/dev-python/py-amqp/py-amqp-2.5.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+MY_PN="amqp"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
+HOMEPAGE="https://github.com/celery/py-amqp https://pypi.org/project/amqp/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc extras test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=""
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       >=dev-python/vine-1.1.3[${PYTHON_USEDEP}]
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               dev-python/sphinx_celery[${PYTHON_USEDEP}]
+       )
+       test? (
+               >=dev-python/case-1.3.1[${PYTHON_USEDEP}]
+               >=dev-python/pytest-3.0[${PYTHON_USEDEP}]
+               dev-python/pytest-cov[${PYTHON_USEDEP}]
+               dev-python/pytest-mock[${PYTHON_USEDEP}]
+               >=dev-python/pytest-rerunfailures-6.0[${PYTHON_USEDEP}]
+       )
+"
+
+python_prepare_all() {
+       # pytest-sugar is not packaged
+       sed -e '/pytest-sugar/d' -i requirements/test.txt || die
+
+       # requires a rabbitmq instance
+       rm t/integration/test_rmq.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/_build/html/. )
+       if use extras; then
+               insinto /usr/share/${PF}/extras
+               doins -r extra
+       fi
+       distutils-r1_python_install_all
+}