dev-games/freecell-solver: 5.24.0 version bump

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/dev-games/freecell-solver/Manifest b/dev-games/freecell-solver/Manifest
index 829a8b93375ea05ed342aa3987b6a28999d4087d..308b112852dc31d9cb973ead07c2e84cc2f5093e 100644 (file)
--- a/dev-games/freecell-solver/Manifest
+++ b/dev-games/freecell-solver/Manifest
@@ -1 +1,2 @@
 DIST freecell-solver-5.22.1.tar.xz 421948 BLAKE2B 173a6bb25110695dfaf590f8339f4728e96ad112788efa73ff05ef311effd48b1e037aaa9ed8446cfe3408012f81bb785e6d7a17d249c95108ca38e2473ee0f7 SHA512 8472ce519168481fcbfa0347d1d86859c7344fe34a58bbef694d22653c02f09e70722bf92e052bda5b3f9bce8cee0f745ac45c9e08712b15c34bb40306f510f6
+DIST freecell-solver-5.24.0.tar.xz 422468 BLAKE2B 3fc98a6ba5116bbbdc79c8c09c820b3992fd666c14736fca98b2191c752b5c5a465dcf4ad3fc79ac944d2189647097aad70f99b140e6feff133bae26d4d52411 SHA512 264a7e016a5dbd093f126aab520b36c98c02111a3834ba09646ba527046973163aeefe41449e05d161d1790d2f599c6a3302402442b96b9bd524e97fc4f54b91

diff --git a/dev-games/freecell-solver/freecell-solver-5.24.0.ebuild b/dev-games/freecell-solver/freecell-solver-5.24.0.ebuild
new file mode 100644 (file)
index 0000000..0dd6348
--- /dev/null
+++ b/dev-games/freecell-solver/freecell-solver-5.24.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake python-single-r1
+
+DESCRIPTION="C library for automatically solving Freecell and some other solitaire variants"
+HOMEPAGE="https://fc-solve.shlomifish.org/"
+SRC_URI="https://fc-solve.shlomifish.org/downloads/fc-solve/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="tcmalloc"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+       $(python_gen_cond_dep '
+               dev-python/pysol_cards[${PYTHON_MULTI_USEDEP}]
+               dev-python/random2[${PYTHON_MULTI_USEDEP}]
+               dev-python/six[${PYTHON_MULTI_USEDEP}]
+       ')
+       tcmalloc? ( dev-util/google-perftools )
+"
+DEPEND="${RDEPEND}
+       dev-perl/Path-Tiny
+       dev-perl/Template-Toolkit
+"
+
+DOCS=( README.html )
+
+PATCHES=( "${FILESDIR}/${PN}-5.22.1-no-docs.patch" )
+
+src_prepare() {
+       python_fix_shebang board_gen
+       cmake_src_prepare
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_STATIC_LIBRARY=OFF
+               -DFCS_BUILD_DOCS=OFF
+               -DFCS_WITH_TEST_SUITE=OFF #requires unpackaged dependencies
+               -DFCS_AVOID_TCMALLOC=$(usex !tcmalloc)
+       )
+
+       cmake_src_configure
+}