net-analyzer/netdata: Unneeded dependencies, remove CONFIG_PROTECT

Do not CONFIG_PROTECT files in /usr/lib64/netdata/conf.d directory
because user should not edit them directly, see
https://github.com/netdata/netdata/blob/master/docs/configuration-guide.md#persist-my-configuration

Remove unnecessary dependencies on net-analyzer/tcpdump and
net-analyzer/traceroute

Bug: https://github.com/gentoo/gentoo/pull/13515
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Craig Andrews <candrews@gentoo.org>

diff --git a/net-analyzer/netdata/netdata-1.18.1-r1.ebuild b/net-analyzer/netdata/netdata-1.18.1-r1.ebuild
new file mode 100644 (file)
index 0000000..9551054
--- /dev/null
+++ b/net-analyzer/netdata/netdata-1.18.1-r1.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit autotools fcaps linux-info python-r1 systemd
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/netdata/${PN}.git"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/netdata/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Linux real time system monitoring, done right!"
+HOMEPAGE="https://github.com/netdata/netdata https://my-netdata.io/"
+
+LICENSE="GPL-3+ MIT BSD"
+SLOT="0"
+IUSE="caps +compression cpu_flags_x86_sse2 cups dbengine ipmi mysql nfacct nodejs postgres +python tor xen"
+REQUIRED_USE="
+       mysql? ( python )
+       python? ( ${PYTHON_REQUIRED_USE} )
+       tor? ( python )"
+
+# most unconditional dependencies are for plugins.d/charts.d.plugin:
+RDEPEND="
+       acct-group/netdata
+       acct-user/netdata
+       app-misc/jq
+       >=app-shells/bash-4:0
+       || (
+               net-analyzer/openbsd-netcat
+               net-analyzer/netcat
+       )
+       net-misc/curl
+       net-misc/wget
+       sys-apps/util-linux
+       virtual/awk
+       caps? ( sys-libs/libcap )
+       cups? ( net-print/cups )
+       dbengine? (
+               dev-libs/libuv
+               app-arch/lz4
+               dev-libs/judy
+               dev-libs/openssl:=
+       )
+       compression? ( sys-libs/zlib )
+       ipmi? ( sys-libs/freeipmi )
+       nfacct? (
+               net-firewall/nfacct
+               net-libs/libmnl
+       )
+       nodejs? ( net-libs/nodejs )
+       python? (
+               ${PYTHON_DEPS}
+               dev-python/pyyaml[${PYTHON_USEDEP}]
+               mysql? (
+                       || (
+                               dev-python/mysqlclient[${PYTHON_USEDEP}]
+                               dev-python/mysql-python[${PYTHON_USEDEP}]
+                       )
+               )
+               postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
+               tor? ( net-libs/stem[${PYTHON_USEDEP}] )
+       )
+       xen? (
+               app-emulation/xen-tools
+               dev-libs/yajl
+       )"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig"
+
+FILECAPS=(
+       'cap_dac_read_search,cap_sys_ptrace+ep' 'usr/libexec/netdata/plugins.d/apps.plugin'
+)
+
+pkg_setup() {
+       linux-info_pkg_setup
+}
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               --localstatedir="${EPREFIX}"/var \
+               --with-user=netdata \
+               --disable-jsonc \
+               $(use_enable cups plugin-cups) \
+               $(use_enable dbengine) \
+               $(use_enable nfacct plugin-nfacct) \
+               $(use_enable ipmi plugin-freeipmi) \
+               $(use_enable xen plugin-xenstat) \
+               $(use_enable cpu_flags_x86_sse2 x86-sse) \
+               $(use_with compression zlib)
+}
+
+src_install() {
+       default
+
+       rm -rf "${D}/var/cache" || die
+
+       # Remove unneeded .keep files
+       find "${ED}" -name ".keep" -delete || die
+
+       fowners -Rc netdata:netdata /var/log/netdata
+       keepdir /var/log/netdata
+       fowners -Rc netdata:netdata /var/lib/netdata
+       keepdir /var/lib/netdata
+       keepdir /var/lib/netdata/registry
+
+       fowners -Rc root:netdata /usr/share/${PN}
+
+       newinitd system/netdata-openrc ${PN}
+       systemd_dounit system/netdata.service
+       insinto /etc/netdata
+       doins system/netdata.conf
+
+       doenvd 99netdata
+}

diff --git a/net-analyzer/netdata/netdata-9999.ebuild b/net-analyzer/netdata/netdata-9999.ebuild
index a9120717c5d01fac39b3d3ac853beda22abb276a..955105404d1208f37fae3f848ed9b53217f01bd6 100644 (file)
--- a/net-analyzer/netdata/netdata-9999.ebuild
+++ b/net-analyzer/netdata/netdata-9999.ebuild
@@ -35,8 +35,6 @@ RDEPEND="
                net-analyzer/openbsd-netcat
                net-analyzer/netcat
        )
-       net-analyzer/tcpdump
-       net-analyzer/traceroute
        net-misc/curl
        net-misc/wget
        sys-apps/util-linux
@@ -123,6 +121,5 @@ src_install() {
        insinto /etc/netdata
        doins system/netdata.conf
 
-       echo "CONFIG_PROTECT=\"${EPREFIX}/usr/$(get_libdir)/netdata/conf.d\"" > 99netdata
        doenvd 99netdata
 }