net-p2p/qbittorrent: Version bump (v4.1.7)

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index bf34f000ba0e52837912d117832bd64513f6ad26..df6729675532f433d831cf5eabf45e2a740a76b0 100644 (file)
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1 +1,2 @@
 DIST qbittorrent-4.1.6.tar.gz 7780676 BLAKE2B fe2572bece5a014d821cf905a13a45f71c63eda661b338a90517a23d257d83f556c1ad1bd064cc2840e9731886d7afaafa36ea50f8c3fe8ff05fc3ec3a12c478 SHA512 14c337257a71a7a6f850bbbbe3effe6f34c299fe71486c1a71160f54ccc7377a5c8e742ca2fd85cf198b2a603fdfee50bdb19b33a10899f86f8499468ca8a735
+DIST qbittorrent-4.1.7.tar.gz 7803389 BLAKE2B 6a8cf01c2bd86b63b629877fd3446db4aedd1591058af24c14dd4b69f0abae7f3ca715190fa0496b1a3ec742d4ee12585dd27e27c1465a1d22a149c2d47608ca SHA512 59fc6dc9696fbcfb9325017dcb5514f866e7f9e9eda9b4487c29c94d445709f1f3fab35f9817b62da75757360239362d77024d708eae48e89dffdde4ed272be4

diff --git a/net-p2p/qbittorrent/qbittorrent-4.1.7.ebuild b/net-p2p/qbittorrent/qbittorrent-4.1.7.ebuild
new file mode 100644 (file)
index 0000000..e4e1c16
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-4.1.7.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="https://www.qbittorrent.org
+         https://github.com/qbittorrent"
+
+if [[ ${PV} == *9999 ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
+else
+       SRC_URI="https://github.com/qbittorrent/qBittorrent/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+       S="${WORKDIR}/qBittorrent-release-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+dbus debug webui +X"
+REQUIRED_USE="dbus? ( X )"
+
+BDEPEND="
+       dev-qt/linguist-tools:5
+       virtual/pkgconfig
+"
+RDEPEND="
+       >=dev-libs/boost-1.62.0-r1:=
+       dev-qt/qtcore:5
+       dev-qt/qtnetwork:5[ssl]
+       >=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5(+),X?]
+       dev-qt/qtxml:5
+       =net-libs/libtorrent-rasterbar-1.1*:0=
+       sys-libs/zlib
+       dbus? ( dev-qt/qtdbus:5 )
+       X? (
+               dev-libs/geoip
+               dev-qt/qtgui:5
+               dev-qt/qtsvg:5
+               dev-qt/qtwidgets:5
+       )"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md TODO )
+
+src_configure() {
+       econf --with-qtsingleapplication=system \
+               $(use_enable dbus qt-dbus) \
+               $(use_enable debug) \
+               $(use_enable webui) \
+               $(use_enable X gui)
+}
+
+src_install() {
+       emake STRIP="/bin/false" INSTALL_ROOT="${D}" install
+       einstalldocs
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+}