games-action/bomberclone: Version bump to 0.11.9, EAPI 7

Closes: https://bugs.gentoo.org/606890
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

diff --git a/games-action/bomberclone/Manifest b/games-action/bomberclone/Manifest
index 0136e5833c569ae66fea6cd7cc414d510017b46f..e795582d44e47730c0230b279a99b6e4118472e9 100644 (file)
--- a/games-action/bomberclone/Manifest
+++ b/games-action/bomberclone/Manifest
@@ -1 +1,2 @@
 DIST bomberclone-0.11.8.tar.bz2 7966452 BLAKE2B ab090be622e891ae803529360d8bd753ac64b9d66b045d06946735a06e9203bf07a32dddd165f038ea484d584383ed760a5bf9e5d206638438ecb10583734225 SHA512 a5e52db43f7f508993231ec13bb2705f60e25cfc21d15c17d9b422c6fc948dc14cc8c4519acfac2e9b7b32a3072dc3a521fbf28b2150a86cfb4099ced72ab79b
+DIST bomberclone-0.11.9.tar.gz 8109837 BLAKE2B b5ec7cc80b2fe4f7517302029e5e943dd673ce910148f5985a9063f19e67c5fbdb21634f8fead60728b900383f24b67b1fc2b27d1a36c07ab1cfae8f228a4fb7 SHA512 80b3db728d7c54bc421a783c7e3753289e1ecb8500e9c8457d92ce226ebe60f47c2b04fd684c1aae57b1c5968ea3d1fce53c9c269a1fc9e685589fdd0513a439

diff --git a/games-action/bomberclone/bomberclone-0.11.9.ebuild b/games-action/bomberclone/bomberclone-0.11.9.ebuild
new file mode 100644 (file)
index 0000000..9958da2
--- /dev/null
+++ b/games-action/bomberclone/bomberclone-0.11.9.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg-utils
+
+DESCRIPTION="Bomberman clone with network game support"
+HOMEPAGE="https://www.bomberclone.de/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~ppc64 ~x86"
+
+DEPEND=">=media-libs/libsdl-1.1.0[video]
+       media-libs/sdl-image[png]
+       media-libs/sdl-mixer[mod]"
+
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.11.8-gcc52.patch
+)
+
+src_prepare() {
+       default
+
+       mv -v configure.{in,ac} || die
+       sed -i 's/configure\.in/configure.ac/g' configure.ac || die
+       eautoreconf
+}
+
+src_configure() {
+       LIBS="-lm" \
+       econf \
+               --disable-werror \
+               --without-x
+}
+
+src_install() {
+       emake \
+               DESTDIR="${D}" \
+               bomberclonedocdir=\${prefix}/share/doc/${PF} \
+               install
+
+       doicon -s 64 data/pixmaps/${PN}.png
+       make_desktop_entry ${PN} Bomberclone
+
+       # Delete useless documentation.
+       rm -v "${ED}"/usr/share/doc/${PF}/{COPYING,INSTALL,*.nsi} || die
+}
+
+pkg_postinst() { xdg_icon_cache_update; }
+pkg_postrm() { xdg_icon_cache_update; }