media-tv/tvheadend: Version bump to 4.2.7, EAPI 7

Closes: https://bugs.gentoo.org/670228
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

diff --git a/media-tv/tvheadend/Manifest b/media-tv/tvheadend/Manifest
index 6c7435bed2c7640c0e352e7208d9c87afa639451..4f11f8ea5bdb310807493b2ed9d95368590e85df 100644 (file)
--- a/media-tv/tvheadend/Manifest
+++ b/media-tv/tvheadend/Manifest
@@ -1 +1,2 @@
 DIST tvheadend-4.2.6.tar.gz 21528720 BLAKE2B 358373bc19bd4c27ddb597bb14e29e2f451d4a1efd075f40c0324d692b5fdcac0d23f2f626ba9d0ca235f7d0c91930c5bf2438d0b6537af187a9fb3fcf36c419 SHA512 6291b0ba1d9af11d5295bf6804988835e746db2d3ebbd465a22e293a1108225c8c361762b78213c881cd15d7dedd16092f28a97c9e5b38f44920848bfbaf9709
+DIST tvheadend-4.2.7.tar.gz 21815613 BLAKE2B 2a90801189901c8129209d9157fbca826e5e46c2641aa08676a44f3076f4dd82c7732e188e87835ce22b19aedea96b8c816733998241a213904c9f9aff1a2537 SHA512 14dd4f452a785359614e2dfe3c210543e0bddf011b8bb994a282cfcff3f3e2573e48636e4c778c7fea39c01318053211e674911fcec3ad5f7b536bdd9e5f5aa9

diff --git a/media-tv/tvheadend/tvheadend-4.2.7.ebuild b/media-tv/tvheadend/tvheadend-4.2.7.ebuild
new file mode 100644 (file)
index 0000000..e72ceb2
--- /dev/null
+++ b/media-tv/tvheadend/tvheadend-4.2.7.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-info systemd toolchain-funcs user
+
+DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
+HOMEPAGE="https://tvheadend.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="+capmt +constcw +cwc dbus debug dvbcsa dvben50221 +dvb +ffmpeg hdhomerun +imagecache +inotify iptv libressl satip systemd +timeshift uriparser xmltv zeroconf zlib"
+
+BDEPEND="
+       sys-devel/gettext
+       virtual/pkgconfig"
+
+RDEPEND="
+       virtual/libiconv
+       dbus? ( sys-apps/dbus )
+       dvbcsa? ( media-libs/libdvbcsa )
+       dvben50221? ( media-tv/linuxtv-dvb-apps )
+       ffmpeg? ( media-video/ffmpeg:0/55.57.57 )
+       hdhomerun? ( media-libs/libhdhomerun )
+       !libressl? ( dev-libs/openssl:= )
+       libressl? ( dev-libs/libressl:= )
+       uriparser? ( dev-libs/uriparser )
+       zeroconf? ( net-dns/avahi )
+       zlib? ( sys-libs/zlib )"
+
+DEPEND="
+       ${RDEPEND}
+       dvb? ( virtual/linuxtv-dvb-headers )"
+
+RDEPEND+="
+       dvb? ( media-tv/dtv-scan-tables )
+       xmltv? ( media-tv/xmltv )"
+
+REQUIRED_USE="dvbcsa? ( || ( capmt constcw cwc dvben50221 ) )"
+
+# Some patches from:
+# https://github.com/rpmfusion/tvheadend
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-4.0.9-use_system_queue.patch
+       "${FILESDIR}"/${PN}-4.2.1-hdhomerun.patch
+       "${FILESDIR}"/${PN}-4.2.2-dtv_scan_tables.patch
+)
+
+DOCS=( README.md )
+
+pkg_setup() {
+       use inotify &&
+               CONFIG_CHECK="~INOTIFY_USER" linux-info_pkg_setup
+
+       enewuser tvheadend -1 -1 /etc/tvheadend video
+}
+
+src_configure() {
+       CC="$(tc-getCC)" \
+       PKG_CONFIG="${CHOST}-pkg-config" \
+       econf \
+               --disable-bundle \
+               --disable-ccache \
+               --disable-dvbscan \
+               --disable-ffmpeg_static \
+               --disable-hdhomerun_static \
+               --nowerror \
+               $(use_enable capmt) \
+               $(use_enable constcw) \
+               $(use_enable cwc) \
+               $(use_enable dbus dbus_1) \
+               $(use_enable debug trace) \
+               $(use_enable dvb linuxdvb) \
+               $(use_enable dvbcsa) \
+               $(use_enable dvben50221) \
+               $(use_enable ffmpeg libav) \
+               $(use_enable hdhomerun hdhomerun_client) \
+               $(use_enable imagecache) \
+               $(use_enable inotify) \
+               $(use_enable iptv) \
+               $(use_enable satip satip_server) \
+               $(use_enable satip satip_client) \
+               $(use_enable systemd libsystemd_daemon) \
+               $(use_enable timeshift) \
+               $(use_enable uriparser) \
+               $(use_enable zeroconf avahi) \
+               $(use_enable zlib)
+}
+
+src_compile() {
+       emake CC="$(tc-getCC)"
+}
+
+src_install() {
+       default
+
+       newinitd "${FILESDIR}"/tvheadend.initd tvheadend
+       newconfd "${FILESDIR}"/tvheadend.confd tvheadend
+
+       use systemd &&
+               systemd_dounit "${FILESDIR}"/tvheadend.service
+
+       dodir /etc/tvheadend
+       fperms 0700 /etc/tvheadend
+       fowners tvheadend:video /etc/tvheadend
+}
+
+pkg_postinst() {
+       elog "The Tvheadend web interface can be reached at:"
+       elog "http://localhost:9981/"
+       elog
+       elog "Make sure that you change the default username"
+       elog "and password via the Configuration / Access control"
+       elog "tab in the web interface."
+}

diff --git a/media-tv/tvheadend/tvheadend-9999.ebuild b/media-tv/tvheadend/tvheadend-9999.ebuild
index 8ee4fdaf118307655448619db6beb72cbfaf6106..96ff9acc83cced8c35f8d47df80ef004afac3027 100644 (file)
--- a/media-tv/tvheadend/tvheadend-9999.ebuild
+++ b/media-tv/tvheadend/tvheadend-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 inherit git-r3 linux-info systemd toolchain-funcs user
 
@@ -15,6 +15,10 @@ KEYWORDS=""
 
 IUSE="dbus debug +ddci dvbcsa +dvb +ffmpeg hdhomerun +imagecache +inotify iptv libressl opus satip systemd +timeshift uriparser vpx x264 x265 xmltv zeroconf zlib"
 
+BDEPEND="
+       sys-devel/gettext
+       virtual/pkgconfig"
+
 RDEPEND="
        virtual/libiconv
        dbus? ( sys-apps/dbus )
@@ -32,8 +36,6 @@ RDEPEND="
 
 DEPEND="
        ${RDEPEND}
-       sys-devel/gettext
-       virtual/pkgconfig
        dvb? ( virtual/linuxtv-dvb-headers )
        ffmpeg? (
                opus? ( media-libs/opus )