dev-libs/libinput: Version bump to 1.15.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index f4f3c70c491e6d876a7abf075691d99d05133c27..bada38662cd6fb0a154605b666d21b31eb678309 100644 (file)
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1,2 +1,3 @@
 DIST libinput-1.14.3.tar.xz 567560 BLAKE2B 76d38b795a5e721a73062e9c37b23bf6739291549cadc66401ef47b1a9afd5766f1d0ed855fc66912e4257fae4b1b813946c67246adb8d8566d5ad9478079636 SHA512 f01d1bd1b25b8060519575644597d35f0c89de5386d298441f440128ceee3e57549921a058adec31adc8b33dbdedf4c0bd12c76905a69f752859d3136e26336d
 DIST libinput-1.15.0.tar.xz 573364 BLAKE2B 521e5775fb98b1b3a281d1002bd41fb0cd3e7dd3d7c1f11bd32773fb8651cddfa7db1fa2ca686a213ecd726f2f0fb475cd3f40a7a7290101286a334fa7b0086d SHA512 5dab48e1b4c9c0deb5b01ebc3ccb4cc28d614be25d87daaf42f51fbd2d955266f3fdba73029bc0094caa55060dad8967751b72d8f45f19a40b542f0c9118c1b6
+DIST libinput-1.15.1.tar.xz 579236 BLAKE2B 0b0b8cd6643ef33c1fc52461caea332d98cee38b79eee3947fc3d853e6a9402ffc9ba2ac5588430c28c73b6444fa06f6743b0c932077ef29e97d0b1384e20fca SHA512 634810359bc4d86f2c4c75f472bee5eaed04ed93af3c91c4bc46a596402323941f9cc90173e278bfa7e5cbda6b7a20adc59bd09520dd4152fc961302b7e57904

diff --git a/dev-libs/libinput/libinput-1.15.1.ebuild b/dev-libs/libinput/libinput-1.15.1.ebuild
new file mode 100644 (file)
index 0000000..d0cb85f
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.15.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2014-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{6,7}} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+BDEPEND="
+       virtual/pkgconfig
+       doc? (
+               $(python_gen_any_dep '
+                       dev-python/commonmark[${PYTHON_USEDEP}]
+                       dev-python/recommonmark[${PYTHON_USEDEP}]
+                       dev-python/sphinx[${PYTHON_USEDEP}]
+                       >=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+               ')
+               >=app-doc/doxygen-1.8.3
+               >=media-gfx/graphviz-2.38.0
+       )
+"
+#      test? ( dev-util/valgrind )
+RDEPEND="
+       input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+       >=dev-libs/libevdev-1.3
+       >=sys-libs/mtdev-1.1
+       virtual/libudev:=
+       virtual/udev
+"
+DEPEND="${RDEPEND}"
+#      test? ( >=dev-libs/check-0.9.10 )
+
+python_check_deps() {
+       has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+       has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+       has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+       has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+       # gui can be built but will not be installed
+       local emesonargs=(
+               -Ddebug-gui=false
+               $(meson_use doc documentation)
+               $(meson_use input_devices_wacom libwacom)
+               -Dtests=false # tests are restricted
+               -Dudev-dir="${EPREFIX}$(get_udevdir)"
+       )
+       meson_src_configure
+}
+
+src_install() {
+       meson_src_install
+       if use doc ; then
+               docinto html
+               dodoc -r "${BUILD_DIR}"/Documentation/.
+       fi
+}
+
+pkg_postinst() {
+       udevadm hwdb --update --root="${ROOT}"
+}