media-sound/gpodder: Version bump

Closes: https://bugs.gentoo.org/615548
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

diff --git a/media-sound/gpodder/Manifest b/media-sound/gpodder/Manifest
index 38bf42e9991ad53e770adc8bb3d866fc0d46c4b2..e14bc183e560540277aa0986e696db7446508964 100644 (file)
--- a/media-sound/gpodder/Manifest
+++ b/media-sound/gpodder/Manifest
@@ -1 +1,2 @@
+DIST gpodder-3.10.5.tar.gz 1000492 BLAKE2B d3c1381fa613e018c79995a5b5d95958096dab49d4b4d9012e8741efe754f7f9db82e7fc46527e1fb837ce8fbfd3c14d58f8af64f96e51c5750b56402767ddca SHA512 056375d7a21f64e691bd62676d575dfaa8a32e715dc4f7ddf7b0c1cb9e99f07cef5972de812765874afd5a8e8adf220eb7b969afcc8dea1e2e3a76be8886c9cc
 DIST gpodder-3.9.1.tar.gz 996497 BLAKE2B ac50cba8d5bf459361c592e579cc9e5deafa3a1a7517f0f5e1f07faa1eaea6456b35451ba2c21def390f85c38f4a95c46cb17a7db4ae4e56c58f79fae6413b11 SHA512 d32405ac1d0aa7943b58d73f806a0d28e68bce541a1947c08d9cb69a763eda311816c059019e43eb3dea6ce08fc1cb4f0bd39cc44933114e51a036cb603d3be3

diff --git a/media-sound/gpodder/gpodder-3.10.5.ebuild b/media-sound/gpodder/gpodder-3.10.5.ebuild
new file mode 100644 (file)
index 0000000..6cc2606
--- /dev/null
+++ b/media-sound/gpodder/gpodder-3.10.5.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils
+
+DESCRIPTION="A free cross-platform podcast aggregator"
+HOMEPAGE="https://gpodder.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus bluetooth kernel_linux mtp test"
+
+# As in Fedora: re-enable >=dev-python/eyeD3-0.7[${PYTHON_USEDEP}] and
+# ipod? ( media-libs/libgpod[python,${PYTHON_USEDEP}] ) once they
+# support python3
+COMMON_DEPEND="
+       dev-python/html5lib[${PYTHON_USEDEP}]
+       dev-python/isort[${PYTHON_USEDEP}]
+       dev-python/pycairo[${PYTHON_USEDEP}]
+       >=dev-python/pygobject-3.22.0:3[${PYTHON_USEDEP}]
+       >=dev-python/podcastparser-0.6.0[${PYTHON_USEDEP}]
+       >=dev-python/mygpoclient-1.8[${PYTHON_USEDEP}]
+       dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+       bluetooth? ( net-wireless/bluez )
+       mtp? ( >=media-libs/libmtp-1.0.0:= )
+"
+RDEPEND="${COMMON_DEPEND}
+       kernel_linux? ( sys-apps/iproute2 )
+"
+DEPEND="${COMMON_DEPEND}
+       dev-util/desktop-file-utils
+       dev-util/intltool
+       sys-apps/help2man
+       test? (
+               dev-python/minimock
+               dev-python/coverage
+       )
+"
+
+src_install() {
+       emake PYTHON=python3 DESTDIR="${D}" install
+       distutils-r1_src_install
+}
+
+src_test() {
+       emake releasetest
+}
+
+pkg_preinst() {
+       gnome2_icon_savelist
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+}