net-libs/gnome-online-accounts: bump to 3.30.2

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 3b03fede0734dd9f81a46e193ab6010e8d997cae..239210b9091803e9911ee235a22efea51db53874 100644 (file)
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-online-accounts-3.24.5.tar.xz 1391332 BLAKE2B 9085cbb0c92bfcd338d5feca7ebdd3e3b15483e47fe29faffb8f9fb474663adeaf8d5cc81673c552652c9444e742f2782fd727c93bf488f5c976bde72d00ddce SHA512 8db35d21f0639e7452ec5cb34455b6d48a77fe0755c525f22e5235abe758f09ad5a4685e5e4912a53def298c76a13b558704a83803b5aabecc13a0f9bc3ae0e4
 DIST gnome-online-accounts-3.28.2.tar.xz 1539640 BLAKE2B ff0e5b5a82617c2f8b53ff51dd6651465e8c9da14a1d484e29c97b17d612fdc535d35855c197da2c826f38e4500b117efbfc929e56318feb58fcc38fdb645a1f SHA512 6fac52c939598817bb3ca44b2e3281c98e3c74d8de5aed30e5ac61187392116393d09a0f900d9e45b0e723a90475dca7edc576a9d567a3fb716b0801e36350ca
+DIST gnome-online-accounts-3.30.2.tar.xz 921284 BLAKE2B 9dc503f73ddda64411f73ac865a0355f318ad13789fac0cf7e7a91d16e53b03dee33acca6752060ce54936cfd5050adb8fadfd121158c0496a3f516e35e8fa45 SHA512 3555421adbfec0e7da1c8f3a47415f6c5bc3eaf8b246cf08eb6ee420286a4b40d11bc6e2514bca937b022b95068c9862438fa632d3385503aba2647a4a57976b

diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.30.2.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.30.2.ebuild
new file mode 100644 (file)
index 0000000..450fa08
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.30.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+       >=dev-libs/glib-2.52:2
+       >=app-crypt/libsecret-0.5
+       >=dev-libs/json-glib-0.16
+       dev-libs/libxml2:2
+       >=net-libs/libsoup-2.42:2.4
+       net-libs/rest:0.7
+       >=net-libs/webkit-gtk-2.12.0:4
+       >=x11-libs/gtk+-3.19.12:3
+       x11-libs/pango
+
+       introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+       kerberos? (
+               app-crypt/gcr:0=[gtk]
+               app-crypt/mit-krb5 )
+"
+#      telepathy? ( net-libs/telepathy-glib )
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+       vala? ( $(vala_depend) )
+       dev-libs/libxslt
+       >=dev-util/gtk-doc-am-1.3
+       >=dev-util/gdbus-codegen-2.30.0
+       >=sys-devel/gettext-0.19.8
+       virtual/pkgconfig
+
+       dev-libs/gobject-introspection-common
+       gnome-base/gnome-common
+"
+
+src_prepare() {
+       use vala && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # TODO: Give users a way to set the G/FB/Windows Live secrets
+       gnome2_src_configure \
+               --disable-static \
+               --enable-backend \
+               --enable-documentation \
+               --enable-exchange \
+               --enable-facebook \
+               --enable-flickr \
+               --enable-foursquare \
+               --enable-imap-smtp \
+               --enable-lastfm \
+               --enable-media-server \
+               --enable-owncloud \
+               --enable-pocket \
+               --enable-todoist \
+               --enable-windows-live \
+               $(usex debug --enable-debug=yes ' ') \
+               $(use_enable kerberos) \
+               $(use_enable introspection) \
+               $(use_enable vala)
+}