x11-misc/qterm: new upstream release

Package-Manager: Portage-2.3.40, Repoman-2.3.9

diff --git a/x11-misc/qterm/Manifest b/x11-misc/qterm/Manifest
index ac1e482161dfd65f47117d3dbbdad308760c9e83..acd52ff6e70df7117c103dc44449522068088a87 100644 (file)
--- a/x11-misc/qterm/Manifest
+++ b/x11-misc/qterm/Manifest
@@ -1 +1,2 @@
 DIST qterm-0.7.1.tar.gz 901169 BLAKE2B ab5337680f49e5f5f0d173585a9b9bc9a8606f086faf03405e2eb7efbf73cc3d9808fa6868deae3fe82e00d0ed2c0ec2d461d3085303b51ee1026bda672d8ddc SHA512 94f4c3f7974572c29eabf98c45e962b9232a4b0fbd6710c7725e0d23e6ecc91456f52a8c112779cd3b4732cb2e4302629419f7365b2d359ccbf39578e6e67cdd
+DIST qterm-0.7.3.tar.gz 901423 BLAKE2B e3f799946bfff4531e77d04fe535d53ef92093d1435aca32b06fa43c444c55798ab1c8408847dde81d1d24b5fda0c4a4f58fb563369f2c4669ba43929695cbd8 SHA512 93fdd24d79a81853654a4702ff55b2fad80c1cc734ec3230a297b3a2613cf24d41f4c645eadc5f34b6025f548e7c8cd5d291d4c29fc919f8966eeb8b44f5c046

diff --git a/x11-misc/qterm/qterm-0.7.3.ebuild b/x11-misc/qterm/qterm-0.7.3.ebuild
new file mode 100644 (file)
index 0000000..8297a40
--- /dev/null
+++ b/x11-misc/qterm/qterm-0.7.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit cmake-utils gnome2-utils xdg-utils
+
+DESCRIPTION="A BBS client based on Qt"
+HOMEPAGE="https://github.com/qterm/qterm"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl"
+
+RDEPEND="dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtmultimedia:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtprintsupport:5
+       dev-qt/qtscript:5[scripttools]
+       dev-qt/qtwidgets:5
+       dev-qt/qtxml:5
+       x11-libs/libX11
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:= )"
+DEPEND="${RDEPEND}
+       dev-qt/linguist-tools:5
+       dev-qt/qthelp:5
+       x11-base/xorg-proto"
+
+PATCHES=( "${FILESDIR}"/${PN}-libressl.patch )
+DOCS=( README.rst RELEASE_NOTES TODO doc/script.txt )
+
+src_prepare() {
+       # file collision with sys-cluster/torque, bug #176533
+       sed -i "/PROGRAME /s/qterm/QTerm/" CMakeLists.txt
+       sed -i "s/Exec=qterm/Exec=QTerm/" src/${PN}.desktop
+
+       cmake-utils_src_prepare
+       xdg_environment_reset
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DQT5=ON
+       )
+       cmake-utils_src_configure
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+}