media-libs/libchamplain: bump to 0.12.5

Also remove --disable-maemo passing - it seems to not exist for a while now.

diff --git a/media-libs/libchamplain/Manifest b/media-libs/libchamplain/Manifest
index c64978922e1e2bcbcbd530ea7e80ceca416e95fe..0de3526a743c6be20284eec2499b917aeb8c09c9 100644 (file)
--- a/media-libs/libchamplain/Manifest
+++ b/media-libs/libchamplain/Manifest
@@ -1 +1,2 @@
 DIST libchamplain-0.12.14.tar.xz 615972 SHA256 f1621ddec1ffe64ca01c3216db8663f60ae0bb107521195fc6856119d4b4568f SHA512 83d69a7dc88be5e056612643fa8d77c7c552758178a4a9e0f4bea908798dd4aeb3423b7cc64db02332f782d91c3da68290a2346363c47c7a83a48d8708b91c6c WHIRLPOOL 1948959c9660f07938218757d973a4c2f4468631ff656ad1782e0c3a8b0b599e9591bd9cfb68919b044154f69553526bef47f1a04135b7b8a479a596baa47ff7
+DIST libchamplain-0.12.15.tar.xz 616692 SHA256 54721a210bdef6d73c5192ed83542023117bf5d7441257e7a7a9f8c05550b874 SHA512 df921dc26e30bc32f6487c02fc3c3f2dc7c672f6f42bd79e05091f717e6545051ab4f0db0709152a5babd4bbd7eb122997682561d9d63bef19bc1b2923100437 WHIRLPOOL 8b771c21cf3227b9f07377d219124b7c8a6ddeefa48db8f9e76e0ef619e01afaab808f7b3ffb5b54baed69a117ff7396f94e82e8abe69e26fd8dff6f9b36a6e5

diff --git a/media-libs/libchamplain/libchamplain-0.12.15.ebuild b/media-libs/libchamplain/libchamplain-0.12.15.ebuild
new file mode 100644 (file)
index 0000000..80a76c7
--- /dev/null
+++ b/media-libs/libchamplain/libchamplain-0.12.15.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Clutter based world map renderer"
+HOMEPAGE="https://wiki.gnome.org/Projects/libchamplain"
+
+SLOT="0.12"
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug +gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+       dev-db/sqlite:3
+       >=dev-libs/glib-2.16:2
+       >=media-libs/clutter-1.12:1.0[introspection?]
+       media-libs/cogl:=
+       >=net-libs/libsoup-2.42:2.4
+       >=x11-libs/cairo-1.4
+       x11-libs/gtk+:3
+       gtk? (
+               x11-libs/gtk+:3[introspection?]
+               media-libs/clutter-gtk:1.0 )
+       introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}
+       dev-util/gtk-doc-am
+       virtual/pkgconfig
+       vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+       # Fix documentation slotability
+       sed \
+               -e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-${SLOT}/" \
+               -i docs/reference/Makefile.{am,in} || die "sed (1) failed"
+       sed \
+               -e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-gtk-${SLOT}/" \
+               -i docs/reference-gtk/Makefile.{am,in} || die "sed (2) failed"
+       mv "${S}"/docs/reference/${PN}{,-${SLOT}}-docs.sgml || die "mv (1) failed"
+       mv "${S}"/docs/reference-gtk/${PN}-gtk{,-${SLOT}}-docs.sgml || die "mv (2) failed"
+
+       use vala && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # Vala demos are only built, so just disable them
+       gnome2_src_configure \
+               --disable-memphis \
+               --disable-static \
+               --disable-vala-demos \
+               $(use_enable debug) \
+               $(use_enable gtk) \
+               $(use_enable introspection) \
+               $(use_enable vala)
+}