dev-libs/libgdata: 0.17.9 → 0.17.10

the package moved to meson and gettext, can't get the tests to work
as they need dconf

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Sobhan Mohammadpour <sobhan@gentoo.org>

diff --git a/dev-libs/libgdata/Manifest b/dev-libs/libgdata/Manifest
index 03a41b0f19e758e7a2cc21447a9e706d12c85d2e..a55d677faa656a7d796ff1879d76f8a214a5a4f9 100644 (file)
--- a/dev-libs/libgdata/Manifest
+++ b/dev-libs/libgdata/Manifest
@@ -1,2 +1,3 @@
+DIST libgdata-0.17.10.tar.xz 836836 BLAKE2B a34f133289eb64ca24d96f38851ac07347e1b2a88860bf926072945d64d3064bbf5c4f674bfb262f27c290fa2b243d5f82805e09290194a9614dbf8dc0993e05 SHA512 01f8bb121c402fc0af8e9f12cafba326a87cef6756ced72652890c834fd4f497a060f6455ab66d4af92d9cd34b4d6fdf58033dca0f91bb806c80b60987955c22
 DIST libgdata-0.17.8.tar.xz 1464812 BLAKE2B 787b5d6e4a62e70f76ca4080fb5c3ff1e7d68745f388be646dd980ef8be18275997bca46a1f3639c9457c8310f9c3f4cd34892be88db284a9ee5e5f43e9723fa SHA512 dfc4c825a7053a6fd7659d04c7077bed8539b4cf3ef3da1d5ece4da3ce17941900e960a300a50b284010ed890dcab87e4c4726403f04481c672832fd34b975b0
 DIST libgdata-0.17.9.tar.xz 1434700 BLAKE2B e0b10bdd962aa5d294d75c15c3aa9187342cd85b9a28816fe5628864bc2236e10ee2765ed8123c8b90422f0394b342a2a144dc7ef844486193c8eec2a46cb17f SHA512 90289309cbdc4ec6932bf385ddbfcc75c0c2f8b9ca356329298aaa37f6c3db7a16de20e5c947c16c595e43e729a664e4d6d3e2c5a60bb1e463a13d1306f374ce

diff --git a/dev-libs/libgdata/libgdata-0.17.10.ebuild b/dev-libs/libgdata/libgdata-0.17.10.ebuild
new file mode 100644 (file)
index 0000000..1125746
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.17.10.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+GNOME2_EAUTORECONF="yes"
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts gtk gtk-doc +introspection test vala"
+# needs dconf
+RESTRICT="test"
+
+REQUIRED_USE="
+       gnome-online-accounts? ( crypt )
+       vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+       >=dev-libs/glib-2.44.0:2
+       >=dev-libs/json-glib-1[introspection?]
+       >=dev-libs/libxml2-2:2
+       >=net-libs/liboauth-0.9.4
+       >=net-libs/libsoup-2.55.90:2.4[introspection?]
+       gtk? ( x11-libs/gtk+:3 )
+       crypt? ( app-crypt/gcr:= )
+       gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:=[introspection?,vala?] )
+       introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+DEPEND="${RDEPEND}
+       dev-util/glib-utils
+       >=dev-util/gtk-doc-am-1.25
+       sys-devel/gettext
+       virtual/pkgconfig
+       gtk-doc? ( dev-util/gtk-doc )
+       test? ( >=net-libs/uhttpmock-0.5
+               >=x11-libs/gdk-pixbuf-2.14:2 )
+       vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+       use vala && vala_src_prepare
+       eapply_user
+}
+
+src_configure() {
+       local emesonargs=(
+               "-Dinstalled_tests=false"
+               -Dgnome=$(usex crypt enabled disabled)
+               -Dgoa=$(usex gnome-online-accounts enabled disabled)
+               -Dgtk=$(usex gtk enabled disabled)
+               $(meson_use gtk-doc gtk_doc)
+               $(meson_use gtk-doc man)
+               $(meson_use introspection)
+               $(meson_use vala vapi)
+               $(meson_use test always-build-tests)
+       )
+       meson_src_configure
+}
+
+src_test() {
+       meson_src_test
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+}
+
+pkg_postrm() {
+       xdg_pkg_postrm
+}