media-libs/libsndfile: bump to v1.0.29_pre2_p20191024

Bug: https://bugs.gentoo.org/631674
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

diff --git a/media-libs/libsndfile/Manifest b/media-libs/libsndfile/Manifest
index 161256fc2f82352e12462cae285c178c53ef1e9e..b425c3f223a3cb9249ee7497e9434be9b200b0dd 100644 (file)
--- a/media-libs/libsndfile/Manifest
+++ b/media-libs/libsndfile/Manifest
@@ -1 +1,2 @@
 DIST libsndfile-1.0.28.tar.gz 1202833 BLAKE2B 102735766e2c22b5278fde43feaaa664598c08fadb5264d5130e4bf1e354bd4202948db38e2912d7487bd7f8c0b9faf1616c0873eed886a56b1d7f49452bf488 SHA512 890731a6b8173f714155ce05eaf6d991b31632c8ab207fbae860968861a107552df26fcf85602df2e7f65502c7256c1b41735e1122485a3a07ddb580aa83b57f
+DIST libsndfile-1.0.29_pre2_p20191024.tar.gz 720981 BLAKE2B 9f1dcf3d3669b66d8582d50b62ff863facd7125432a84a3e1e3fb0f817554f260f42948b4479371fb0967dcc75bedc6c49afffc6bee3f973a875d72d2e508210 SHA512 e37b385b90cadc97348db03b6c5ae7a8fcee17ded60f54d1508adddb8e2dc604ea44b60a0fe08627e81c0faa83997cdafb0b0ecf8574f901bf5e8a1819a63998

diff --git a/media-libs/libsndfile/libsndfile-1.0.29_pre2_p20191024.ebuild b/media-libs/libsndfile/libsndfile-1.0.29_pre2_p20191024.ebuild
new file mode 100644 (file)
index 0000000..c4cf210
--- /dev/null
+++ b/media-libs/libsndfile/libsndfile-1.0.29_pre2_p20191024.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} pypy{,3} )
+
+inherit autotools python-any-r1 multilib-minimal
+
+MY_COMMIT="97a361afc24202b16489d8c06910277c06b18b53"
+
+SRC_URI="https://github.com/erikd/libsndfile/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+DESCRIPTION="C library for reading and writing files containing sampled sound"
+HOMEPAGE="http://www.mega-nerd.com/libsndfile"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="alsa minimal sqlite static-libs test"
+
+RDEPEND="
+       !minimal? (
+               >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}]
+               >=media-libs/libogg-1.3.0:=[${MULTILIB_USEDEP}]
+               >=media-libs/libvorbis-1.3.3-r1:=[${MULTILIB_USEDEP}]
+               >=media-libs/opus-1.1:=[${MULTILIB_USEDEP}]
+       )
+       alsa? ( media-libs/alsa-lib:= )
+       sqlite? ( >=dev-db/sqlite-3.2 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       virtual/pkgconfig
+       ${PYTHON_DEPS}
+       sys-devel/autogen
+       "
+
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+pkg_setup() {
+       python-any-r1_pkg_setup
+}
+
+src_prepare() {
+       default
+
+       eautoreconf
+}
+
+multilib_src_configure() {
+       ECONF_SOURCE="${S}" econf \
+               --disable-octave \
+               $(use_enable static-libs static) \
+               $(use_enable !minimal external-libs) \
+               $(multilib_native_enable full-suite) \
+               $(multilib_native_use_enable alsa) \
+               $(multilib_native_use_enable sqlite) \
+               PYTHON="${EPYTHON}"
+}
+
+multilib_src_install_all() {
+       einstalldocs
+
+       # package provides .pc files
+       find "${D}" -name '*.la' -delete || die
+}

diff --git a/media-libs/libsndfile/libsndfile-9999.ebuild b/media-libs/libsndfile/libsndfile-9999.ebuild
index aa94640fb8f209a9c7e3075e41cd850f77e86600..d618e1668362c2a2f5bea9859d00dfad5e87d22d 100644 (file)
--- a/media-libs/libsndfile/libsndfile-9999.ebuild
+++ b/media-libs/libsndfile/libsndfile-9999.ebuild
@@ -26,6 +26,7 @@ RDEPEND="
                >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}]
                >=media-libs/libogg-1.3.0:=[${MULTILIB_USEDEP}]
                >=media-libs/libvorbis-1.3.3-r1:=[${MULTILIB_USEDEP}]
+               >=media-libs/opus-1.1:=[${MULTILIB_USEDEP}]
        )
        alsa? ( media-libs/alsa-lib:= )
        sqlite? ( >=dev-db/sqlite-3.2 )"