x11-libs/libyui-qt: 2.47.1 version bump, EAPI-6, missing deps

Package-Manager: Portage-2.3.48, Repoman-2.3.10

diff --git a/x11-libs/libyui-qt/Manifest b/x11-libs/libyui-qt/Manifest
index 7462540db94473388a46471893cf920c66bc2c39..aaff0b32b0897acb9fb1821aa14506528af69d36 100644 (file)
--- a/x11-libs/libyui-qt/Manifest
+++ b/x11-libs/libyui-qt/Manifest
@@ -1 +1,2 @@
 DIST libyui-qt-2.46.21.tar.gz 167324 BLAKE2B 175df2de97b013e81298dd8f2c66d099047d6d8ae2ca56f9c92d2b634a5acbdd92bcd3c4d0243a4e013267eeb563366229440b7cdf160ea888dc5b85e12984e0 SHA512 715154efd9fa2753f528e5a809fd2a3c635751b9bee3d511e396051b04a55086446510dbec5c70e753b1926c35faf84aaf05ea92a2a7f089f9b95dce9ee1a77f
+DIST libyui-qt-2.47.1.tar.gz 171152 BLAKE2B 54a8d1609ed717e97c1ec9b3eb6e86eed85446689223753db4b2dcb4c35f361675c42287378636708813b724c4120b14b6bab19c4c8fa17f91bbb612569d1a00 SHA512 9c5e23ff7bb08dd363a490a43c0347e4dbe1af3546bec85a9169da3267f87cbbe15f17f882058b2f3a813fb54efeb1594ec343b2b8d12e371ee77a105a8f4f99

diff --git a/x11-libs/libyui-qt/libyui-qt-2.47.1.ebuild b/x11-libs/libyui-qt/libyui-qt-2.47.1.ebuild
new file mode 100644 (file)
index 0000000..3672afb
--- /dev/null
+++ b/x11-libs/libyui-qt/libyui-qt-2.47.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="UI abstraction library - Qt plugin"
+HOMEPAGE="https://github.com/libyui/libyui-qt"
+SRC_URI="https://github.com/libyui/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/6"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="static-libs"
+
+RDEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtwidgets:5
+       dev-qt/qtx11extras:5
+       media-libs/freetype
+       x11-libs/libX11
+       x11-libs/libyui:${SLOT}
+"
+# Only Boost headers are needed
+# QtSvg headers only required, no linking
+DEPEND="${RDEPEND}
+       dev-libs/boost
+       dev-qt/qtsvg:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-2.46.21-norpc.patch" )
+
+src_prepare() {
+       cp "${EPREFIX}/usr/share/libyui/buildtools/CMakeLists.common" CMakeLists.txt || die
+
+       # TODO: set proper docs deps and USE flag for building them
+       sed -i -e '/SET_AUTODOCS/d' CMakeLists.txt || die 'sed on CMakeLists.txt failed'
+       sed -i -e 's/src examples/src/' PROJECTINFO.cmake || die 'sed on PROJECTINFO.cmake failed'
+
+       cmake-utils_src_prepare
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DENABLE_EXAMPLES=OFF
+               -DENABLE_WERROR=OFF
+               -DDOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+               -DRESPECT_FLAGS=ON
+               -DENABLE_STATIC=$(usex static-libs)
+       )
+       cmake-utils_src_configure
+}