media-sound/mac: Revision bump to 4.11.4.5.7-r1. Switch to EAPI 7.

Signed-off-by: Daniel Pielmeier <billie@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

diff --git a/media-sound/mac/files/mac-4.11.4.5.7-null.patch b/media-sound/mac/files/mac-4.11.4.5.7-null.patch
new file mode 100644 (file)
index 0000000..fa1f359
--- /dev/null
+++ b/media-sound/mac/files/mac-4.11.4.5.7-null.patch
@@ -0,0 +1,12 @@
+diff -Naur monkeys-audio-4.11-u4-b5-s7_old/src/Console/Console.cpp monkeys-audio-4.11-u4-b5-s7/src/Console/Console.cpp
+--- monkeys-audio-4.11-u4-b5-s7_old/src/Console/Console.cpp    2017-03-04 17:52:24.154352673 +0100
++++ monkeys-audio-4.11-u4-b5-s7/src/Console/Console.cpp        2017-03-04 17:52:31.400352385 +0100
+@@ -51,7 +51,7 @@
+ 
+ _ErrorDesc ErrorList[][2] = {
+   ERROR_EXPLANATION
+-  NULL
++  0
+ };
+ #endif
+ 

diff --git a/media-sound/mac/mac-4.11.4.5.7-r1.ebuild b/media-sound/mac/mac-4.11.4.5.7-r1.ebuild
new file mode 100644 (file)
index 0000000..aa65b9a
--- /dev/null
+++ b/media-sound/mac/mac-4.11.4.5.7-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_PN=monkeys-audio
+MY_PV=$(ver_cut 1-2)-u$(ver_cut 3)-b$(ver_cut 4)-s$(ver_cut 5)
+MY_P=${MY_PN}_${MY_PV}
+
+DESCRIPTION="Monkey's Audio Codecs"
+HOMEPAGE="http://etree.org/shnutils/shntool/ http://www.deb-multimedia.org/dists/testing/main/binary-amd64/package/monkeys-audio.php"
+SRC_URI="http://www.deb-multimedia.org/pool/main/m/monkeys-audio/${MY_P}.orig.tar.gz"
+
+LICENSE="mac"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
+IUSE="cpu_flags_x86_mmx static-libs"
+
+RDEPEND=""
+DEPEND="
+       sys-apps/sed
+       cpu_flags_x86_mmx? ( dev-lang/yasm )
+"
+
+S=${WORKDIR}/${MY_P/_/-}
+
+PATCHES=(
+       "${FILESDIR}"/${P}-output.patch
+       "${FILESDIR}"/${P}-gcc6.patch
+       "${FILESDIR}"/${P}-null.patch
+)
+
+DOCS=( AUTHORS ChangeLog NEWS TODO README src/History.txt src/Credits.txt ChangeLog.shntool )
+
+RESTRICT="mirror"
+
+src_prepare() {
+       default
+
+       sed -i -e 's:-O3::' configure || die
+}
+
+src_configure() {
+       append-cppflags -DSHNTOOL
+       use cpu_flags_x86_mmx && append-ldflags -Wl,-z,noexecstack
+
+       econf \
+               $(use_enable static-libs static) \
+               $(use_enable cpu_flags_x86_mmx assembly)
+}
+
+src_install() {
+       default
+
+       insinto /usr/include/${PN}
+       doins src/MACLib/{BitArray,UnBitArrayBase,Prepare}.h #409435
+
+       find "${D}" -name '*.la' -delete || die
+}