media-sound/jack2: bump to 1.9.14 + 9999 sync

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

diff --git a/media-sound/jack2/Manifest b/media-sound/jack2/Manifest
index 0d68e059bfd5f1559516a69db1018df0281ef140..2ee85696e18f9b0d19a3a17a2e520c787463a86f 100644 (file)
--- a/media-sound/jack2/Manifest
+++ b/media-sound/jack2/Manifest
@@ -1 +1,2 @@
 DIST jack2-1.9.13.tar.gz 6485870 BLAKE2B 7acc0a1389af133dafa7368b4285c2a06607d84015601f2d8afbd63a9a08f40210f8206f2febbd0e5cc651513a59419e1d948a56163d2074c4b77da5edd84a52 SHA512 dd83a6535cf92a3c45b5ed31edda5f1cb4a6c1db2ac683d4ea709e226bc30d55b366ce80ee543dfaa600f871079f3754e9314124093e230dc7deeceb828de8aa
+DIST jack2-1.9.14.tar.gz 6495043 BLAKE2B 9ace1cef2c15c2894831c79bb8d73637df27a21462f654e04b7fb8fc05731e6df898aaefc343a9be4799bcd70576aa7397f2d48b7d2530b682f62463ce3d4a07 SHA512 ca9738fd5aadcb7e125f98a358437905959afebe0b792cab316fc31410e89ea3aefdb85154792a9d0a80fa988aa7eff379ff5c7ac6c4bfa1d57ad3d7de7b5fdd

diff --git a/media-sound/jack2/jack2-1.9.14.ebuild b/media-sound/jack2/jack2-1.9.14.ebuild
new file mode 100644 (file)
index 0000000..102ddce
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.14.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="threads(+)"
+inherit python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="http://jackaudio.org/"
+
+if [[ "${PV}" = "9999" ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+else
+       MY_PV="${PV/_rc/-RC}"
+       MY_P="${PN}-${MY_PV}"
+       S="${WORKDIR}/${MY_P}"
+       SRC_URI="https://github.com/jackaudio/jack2/releases/download/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
+
+REQUIRED_USE="
+       ${PYTHON_REQUIRED_USE}
+       || ( classic dbus )"
+
+CDEPEND="${PYTHON_DEPS}
+       media-libs/libsamplerate
+       media-libs/libsndfile
+       sys-libs/readline:0=
+       alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+       dbus? (
+               dev-libs/expat[${MULTILIB_USEDEP}]
+               sys-apps/dbus[${MULTILIB_USEDEP}]
+       )
+       ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
+       metadata? ( sys-libs/db:* )
+       opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+DEPEND="${CDEPEND}
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen )"
+RDEPEND="${CDEPEND}
+       dbus? (
+               $(python_gen_cond_dep '
+                       dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
+               ')
+       )
+       pam? ( sys-auth/realtime-base )
+       !media-sound/jack-audio-connection-kit:0"
+
+DOCS=( ChangeLog.rst README.rst README_NETJACK2 )
+
+src_prepare() {
+       default
+       multilib_copy_sources
+}
+
+multilib_src_configure() {
+       local mywafconfargs=(
+               --htmldir=/usr/share/doc/${PF}/html
+               $(usex dbus --dbus "")
+               $(usex classic --classic "")
+               --alsa=$(usex alsa yes no)
+               --celt=no
+               --db=$(usex metadata yes no)
+               --doxygen=$(multilib_native_usex doc yes no)
+               --firewire=$(usex ieee1394 yes no)
+               --iio=no
+               --opus=$(usex opus yes no)
+               --portaudio=no
+               --readline=$(multilib_native_usex readline yes no)
+               --samplerate=$(multilib_native_usex libsamplerate yes no)
+               --sndfile=$(multilib_native_usex sndfile yes no)
+               --winmme=no
+       )
+
+       waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+       WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+}
+
+multilib_src_install() {
+       WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+       python_fix_shebang "${ED}"
+}

diff --git a/media-sound/jack2/jack2-9999.ebuild b/media-sound/jack2/jack2-9999.ebuild
index 28cd775b1150e9244e745d01e8d0191fba071b87..4259cdfc0dfaf3889ff62aad0475bdc84ee0ff98 100644 (file)
--- a/media-sound/jack2/jack2-9999.ebuild
+++ b/media-sound/jack2/jack2-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=6
 
-PYTHON_COMPAT=( python3_6 python3_7 )
+PYTHON_COMPAT=( python3_{6,7,8} )
 PYTHON_REQ_USE="threads(+)"
 inherit python-single-r1 waf-utils multilib-minimal
 
@@ -17,7 +17,7 @@ else
        MY_PV="${PV/_rc/-RC}"
        MY_P="${PN}-${MY_PV}"
        S="${WORKDIR}/${MY_P}"
-       SRC_URI="https://github.com/jackaudio/jack2/releases/download/v${MY_PV}/${MY_P}.tar.gz"
+       SRC_URI="SRC_URI="https://github.com/jackaudio/jack2/releases/download/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz""
        KEYWORDS="~amd64 ~ppc ~x86"
 fi