dev-python/python-efl: bump to 1.24.0

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

diff --git a/dev-python/python-efl/Manifest b/dev-python/python-efl/Manifest
index 55ba63638738761eb69dbb897bc2660b03035e02..3e2ca161f2d48652767f0a2c39eef0822516d675 100644 (file)
--- a/dev-python/python-efl/Manifest
+++ b/dev-python/python-efl/Manifest
@@ -1 +1,2 @@
 DIST python-efl-1.23.0.tar.xz 9524832 BLAKE2B d738d3481a0805490c756d38fe169e7d54d9b4c8d6b18ba45265db029b28e59eec8d711675c3fcd52500e19cda8cabc49fb0a2d052d2b9be7800ff9f6dc78f75 SHA512 b2c4389795d704b8f0d8f2d0703b90b09daaeacf7a2d4b372d86f9e0b8f9e2f5b465f8651a0da7cb4bc1800357c317b9cb737afcb415fc0a4cdf4cbed62bdf85
+DIST python-efl-1.24.0.tar.xz 9535212 BLAKE2B ab9535d60af75422f3c055e56f3c6297f595afbf682970afcb21f597486b307504fa83ab894c2029fb681dda8d886d1fc837726d1c4ae62df7185fbc0073724a SHA512 5b57de58b2351f00f744454e6aaa16f7bf9cf72b7f73d07a2d98cda4d152eb65810513b5c04b1eda127b6f5caf56e4b9bc9a7c1ef98593edde26a9ed3be953c9

diff --git a/dev-python/python-efl/python-efl-1.24.0.ebuild b/dev-python/python-efl/python-efl-1.24.0.ebuild
new file mode 100644 (file)
index 0000000..c084d1a
--- /dev/null
+++ b/dev-python/python-efl/python-efl-1.24.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Python bindings for Enlightenment Foundation Libraries"
+HOMEPAGE="https://phab.enlightenment.org/w/projects/python_bindings_for_efl/"
+SRC_URI="https://download.enlightenment.org/rel/bindings/python/${P}.tar.xz"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="=dev-libs/efl-1.24*
+       dev-python/dbus-python[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       dev-python/cython[${PYTHON_USEDEP}]"
+BDEPEND="virtual/pkgconfig
+       doc? (
+               dev-python/sphinx[${PYTHON_USEDEP}]
+               media-gfx/graphviz
+       )"
+
+src_prepare() {
+       default
+
+       # Tries to download a file under /tmp
+       rm tests/ecore/test_09_file_download.py || die
+
+       # Tries to use that file which failed to download
+       rm tests/ecore/test_10_file_monitor.py || die
+
+       # Needs an active internet connection
+       rm tests/ecore/test_11_con.py || die
+
+       # Test fails because of deleted files above
+       sed -i 's/>= 13/>= 10/g' tests/ecore/test_08_exe.py || die
+
+       # Make tests verbose
+       sed -i 's:verbosity=1:verbosity=3:' tests/00_run_all_tests.py || die
+
+       # Disable any optimization on x86, #704260
+       if use x86; then
+               filter-flags -O?
+               append-cflags -O0
+       fi
+}
+
+python_compile_all() {
+       if use doc ; then
+               esetup.py build_doc --build-dir "${S}"/build/doc/
+       fi
+
+       distutils-r1_python_compile
+}
+
+python_test() {
+       cd tests/ || die
+       ${EPYTHON} 00_run_all_tests.py --verbose || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( ./build/doc/html/. )
+       distutils-r1_python_install_all
+}