www-client/opera-developer: Version 67.0.3536.0

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index b80c9587ba3de06791ad488c3582b865a9238bdb..f6927e7a484f229686551b99db8d4f7b60e58358 100644 (file)
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1 +1,2 @@
 DIST opera-developer_67.0.3523.0_amd64.deb 67009858 BLAKE2B 7762c61e51bc182bc8d9c45967b7358a7f907f3d3e99ce00aac1643fa3b414cefdfa25dda7be42e840f6537702485136713ffebeb4d65335aff63cd29101e8da SHA512 37abf5f562f4eb21107583a6d418d2da0cfd74590532ee1d37cb2f8bd4edf0d4c2f6e36172e4ed7ca65ad23f4b6bf8226d1de03a1328d9a81c66b37c7ee85fbb
+DIST opera-developer_67.0.3536.0_amd64.deb 65818504 BLAKE2B f724ed0d695a13a9e3e002c754d6e620a229ac90f199c0b5f26d06cb6ebaddf9320a010cd4a57b3f8603bb19783e74927fcad586c2b0bb9ac3ccb92ec85dede0 SHA512 ddfad9abadff692b0f3a433512b0e780d22134c8b2689b97ff1e7f60c54a4473f437036dc9f202bb48e014561df56584b19dd717a1c71883c149983f5224235d

diff --git a/www-client/opera-developer/opera-developer-67.0.3536.0.ebuild b/www-client/opera-developer/opera-developer-67.0.3536.0.ebuild
new file mode 100644 (file)
index 0000000..132f88d
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-67.0.3536.0.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+       be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+       ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+       zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+       https://download1.operacdn.com/pub/
+       https://download2.operacdn.com/pub/
+       https://download3.operacdn.com/pub/
+       https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+       "${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+       dev-libs/expat
+       dev-libs/glib:2
+       dev-libs/nspr
+       dev-libs/nss
+       gnome-base/gconf:2
+       media-libs/alsa-lib
+       media-libs/fontconfig
+       media-libs/freetype
+       net-misc/curl
+       net-print/cups
+       sys-apps/dbus
+       x11-libs/cairo
+       x11-libs/gdk-pixbuf
+       x11-libs/gtk+:3
+       x11-libs/libX11
+       x11-libs/libXScrnSaver
+       x11-libs/libXcomposite
+       x11-libs/libXcursor
+       x11-libs/libXdamage
+       x11-libs/libXext
+       x11-libs/libXfixes
+       x11-libs/libXi
+       x11-libs/libXrandr
+       x11-libs/libXrender
+       x11-libs/libXtst
+       x11-libs/libnotify
+       x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+       unpack_deb ${A}
+}
+
+pkg_setup() {
+       OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+       default
+
+       case ${ARCH} in
+               amd64)
+                       mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+                       rm -r usr/lib || die
+                       ;;
+               x86)
+                       mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+                       ;;
+       esac
+
+       mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+       gunzip usr/share/doc/${PF}/changelog.gz || die
+
+       rm usr/bin/${PN} || die
+
+       pushd "${OPERA_HOME}/localization" > /dev/null || die
+       chromium_remove_language_paks
+       popd > /dev/null || die
+
+       sed -i \
+               -e 's|^TargetEnvironment|X-&|g' \
+               usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+       mv * "${D}" || die
+       dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+       fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+       xdg_mimeinfo_database_update
+}