dev-libs/fcgi: Port to EAPI 7

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/dev-libs/fcgi/fcgi-2.4.1_pre0910052249-r2.ebuild b/dev-libs/fcgi/fcgi-2.4.1_pre0910052249-r2.ebuild
index ce2b68111c932efb436037a8adcf6b1d2784a74e..2cf2e56dae2cccb7f77a8adee49c42446316193a 100644 (file)
--- a/dev-libs/fcgi/fcgi-2.4.1_pre0910052249-r2.ebuild
+++ b/dev-libs/fcgi/fcgi-2.4.1_pre0910052249-r2.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="4"
+EAPI=7
 
-inherit eutils autotools multilib
+inherit autotools
 
 DESCRIPTION="FastCGI Developer's Kit"
 HOMEPAGE="http://www.fastcgi.com/"
@@ -14,38 +14,43 @@ SLOT="0"
 KEYWORDS="~alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
 IUSE="html"
 
-DEPEND=""
-RDEPEND=""
+S="${WORKDIR}/${PN}-2.4.1-SNAP-0910052249"
 
-S="${WORKDIR}/fcgi-2.4.1-SNAP-0910052249"
+PATCHES=(
+       "${FILESDIR}"/${PN}-2.4.0-Makefile.patch
+       "${FILESDIR}"/${PN}-2.4.0-clientdata-pointer.patch
+       "${FILESDIR}"/${PN}-2.4.0-html-updates.patch
+       "${FILESDIR}"/${PN}-2.4.1_pre0311112127-gcc44.patch
+       "${FILESDIR}"/${P}-link.patch
+       "${FILESDIR}"/${P}-poll.patch
+)
 
 src_prepare() {
-       epatch "${FILESDIR}/fcgi-2.4.0-Makefile.patch"
-       epatch "${FILESDIR}/fcgi-2.4.0-clientdata-pointer.patch"
-       epatch "${FILESDIR}/fcgi-2.4.0-html-updates.patch"
-       epatch "${FILESDIR}"/fcgi-2.4.1_pre0311112127-gcc44.patch
-       epatch "${FILESDIR}"/${P}-link.patch
-       epatch "${FILESDIR}"/${P}-poll.patch
-
+       default
        eautoreconf
 }
 
-src_install() {
-       emake DESTDIR="${D}" install LIBRARY_PATH="${ED}/usr/$(get_libdir)"
+src_configure() {
+       econf --disable-static
+}
 
-       dodoc README
+src_install() {
+       emake DESTDIR="${D}" install LIBRARY_PATH="${ED}"/usr/$(get_libdir)
+       einstalldocs
 
        # install the manpages into the right place
        doman doc/*.[13]
 
        # Only install the html documentation if USE=html
-       if use html ; then
-               dohtml "${S}"/doc/*/*
-               insinto /usr/share/doc/${PF}/html
-               doins -r "${S}/images"
+       if use html; then
+               docinto html
+               dodoc -r doc/*/* images
        fi
 
        # install examples in the right place
-       insinto /usr/share/doc/${PF}/examples
-       doins "${S}/examples/"*.c
+       docinto examples
+       dodoc examples/*.c
+
+       # no static archives
+       find "${D}" -name '*.la' -delete || die
 }