dev-python/clang-python: Bump to 6.0.0rc2

diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index 47974bf00682df67684454f1a9fa22e8f219df5a..606f508ecdcfc1f77a55fb6b3b99aa91a060ee6a 100644 (file)
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -1,2 +1,3 @@
 DIST cfe-4.0.1.src.tar.xz 10933628 BLAKE2B bc1bb8875e83ccecd446a48cfa41f5c98a09d6ad24ff439a983f629711b4513b9c4bee4070f8df13b6b2a52d673b0706733a4c151ce5021a0233147debff14ac SHA512 936c9e1626b27e63a4fb11f3c0cb998eeaf9a520ad6e2bcd67cb4352e59e7781ecc700df79794f3fd70473d90b7e2ba418a39038eb0146b68e843f0705c1f964
 DIST cfe-5.0.1.src.tar.xz 11483036 BLAKE2B c4eb54cd8271b62cf7a2219db0b599b68c00b6e574d1946220efbd1633e841796e6717d6eeb35e84a6db32a731a3285b59cedeb3b1a8f3c3c502b799fdd0a720 SHA512 6619177a2ff9934fe8b15d6aa229abb8e34d0b1a75228d9efba9393daf71d6419a7256de57b31e2f9f829f71f842118556f996e86ee076f1e0a7cd394dfd31a2
+DIST cfe-6.0.0rc2.src.tar.xz 11957996 BLAKE2B 65cd91d8b5591e6312f9b46c1deecca5e14db72f58830b5249ca0fbc3b0911ae5bf60c9e1e326cad6eb670d5f2a144229b4e04e5b7645e516b2a530e428cc171 SHA512 991c45ee8500bee1e7004172e2ab8fa78e3d412b1474cfb48ee6f49232afe8d2f512e2ebf148afc4f8b38cff0110e3af26bdbec2138d80592c876452a18c63fe

diff --git a/dev-python/clang-python/clang-python-6.0.0_rc2.ebuild b/dev-python/clang-python/clang-python-6.0.0_rc2.ebuild
new file mode 100644 (file)
index 0000000..5290aac
--- /dev/null
+++ b/dev-python/clang-python/clang-python-6.0.0_rc2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+inherit python-r1
+
+MY_P=cfe-${PV/_/}.src
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+SRC_URI="http://prereleases.llvm.org/${PV/_//}/${MY_P}.tar.xz"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+       >=sys-devel/clang-${PV}:*
+       !sys-devel/llvm:0[clang(-),python(-)]
+       !sys-devel/clang:0[python(-)]
+       ${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}/bindings/python
+
+src_unpack() {
+       einfo "Unpacking parts of ${MY_P}.tar.xz ..."
+       tar -xJf "${DISTDIR}/${MY_P}.tar.xz" "${MY_P}/bindings/python" || die
+}
+
+src_test() {
+       python_foreach_impl python -m unittest discover -v || die
+}
+
+src_install() {
+       python_foreach_impl python_domodule clang
+}