x11-apps/radeon-profile-daemon: Bump to version 20190603

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

diff --git a/x11-apps/radeon-profile-daemon/Manifest b/x11-apps/radeon-profile-daemon/Manifest
index 636a758f2f60c13ed701cfd15cc69fd1ceb2909a..dae73dc833e0c8237c73a32355d82a9d34c4420b 100644 (file)
--- a/x11-apps/radeon-profile-daemon/Manifest
+++ b/x11-apps/radeon-profile-daemon/Manifest
@@ -1 +1,2 @@
 DIST radeon-profile-daemon-20190309.tar.gz 12178 BLAKE2B 931ce4bb123456e349a68c8fe0b18150ff988a83a5e58cf451f68025240a8b4c802e03a567ef41684e91442bf21c02cc00d31ef6c82a67ca7eb7587754c6f32e SHA512 f2bb6f7dc0bf322e5c43c5ca1f99501a4fd3f4532cc9c1686b5cfbc58bdd423e81c25d3ae03fcae9dc15dc92d8ad089b2357b27b0ff399de7ac27213e00b2f37
+DIST radeon-profile-daemon-20190603.tar.gz 12232 BLAKE2B 3ff02f76178c2a30c8f094a2589aaed7d9e2c8ecc4cd0c8d3b6be1e38dddad39bbb4996ef9b7f87ef999890fbdade6ba3c6bcc39de6ae84bf1c224152a8249f1 SHA512 1c58008400f5acc5bd39353c6e2c109adecc4eb2b5d7976ce240d372cc60996ee93ce50630292ce85b9a1ae92d82e6cce49fd0ccb28f574bc668d212c50a54ab

diff --git a/x11-apps/radeon-profile-daemon/radeon-profile-daemon-20190603.ebuild b/x11-apps/radeon-profile-daemon/radeon-profile-daemon-20190603.ebuild
new file mode 100644 (file)
index 0000000..77f7239
--- /dev/null
+++ b/x11-apps/radeon-profile-daemon/radeon-profile-daemon-20190603.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils systemd
+
+DESCRIPTION="Daemon for radeon-profile GUI"
+HOMEPAGE="https://github.com/marazmista/radeon-profile-daemon"
+if [[ "${PV}" == 99999999 ]] ; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/marazmista/radeon-profile-daemon.git"
+else
+       SRC_URI="https://github.com/marazmista/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE=""
+
+RDEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtnetwork:5
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${P}/${PN}"
+
+PATCHES=(
+       "${FILESDIR}/${PN}-20190603-secure_socket.patch"
+)
+
+src_prepare() {
+       eapply -p2 "${PATCHES[@]}"
+       eapply_user
+
+       sed \
+               -e '/^bin\.path/s@/bin@/sbin@' \
+               -e "/^service\.path/s@=.*\$@= $(systemd_get_systemunitdir)@" \
+               -i radeon-profile-daemon.pro || die
+       sed \
+               -e '/^ExecStart/s@/bin/@/sbin/@' \
+               -i extra/${PN}.service || die
+}
+
+src_configure() {
+       eqmake5
+}
+
+src_install() {
+       emake INSTALL_ROOT="${D}" install
+
+       newinitd "${FILESDIR}"/${PN}.initd-r1 ${PN}
+}
+
+pkg_postinst() {
+       elog "Users need to be in the \"video\" group if they want to change"
+       elog "video card settings via ${PN}"
+}