dev-python/setuptools: Unbundle packaging again

Package-Manager: portage-2.2.20.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

diff --git a/dev-python/setuptools/setuptools-18.2-r3.ebuild b/dev-python/setuptools/setuptools-18.2-r3.ebuild
new file mode 100644 (file)
index 0000000..8843a3f
--- /dev/null
+++ b/dev-python/setuptools/setuptools-18.2-r3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://pypi.python.org/pypi/setuptools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND=">=dev-python/packaging-15.3-r1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       test? (
+               dev-python/pytest[${PYTHON_USEDEP}]
+               dev-python/mock[${PYTHON_USEDEP}]
+       )
+"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( README.txt docs/{easy_install.txt,pkg_resources.txt,setuptools.txt} )
+
+python_prepare_all() {
+       rm -r ./pkg_resources/_vendor || die
+       # disable tests requiring a network connection
+       rm setuptools/tests/test_packageindex.py || die
+
+       # don't run integration tests
+       rm setuptools/tests/test_integration.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       # test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+       # It tries to sandbox the test in a tempdir
+       HOME="${PWD}" py.test ${PN} || die "Tests failed under ${EPYTHON}"
+}
+
+python_install() {
+       export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+       distutils-r1_python_install
+}