dev-python/PyQtWebEngine: add 5.13.0

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

diff --git a/dev-python/PyQtWebEngine/Manifest b/dev-python/PyQtWebEngine/Manifest
index f8fee8555502f49d7064fe6bea1c85c5f84d2df2..f074805f8543e030930bc2161111d6fde71770c6 100644 (file)
--- a/dev-python/PyQtWebEngine/Manifest
+++ b/dev-python/PyQtWebEngine/Manifest
@@ -1 +1,2 @@
 DIST PyQtWebEngine_gpl-5.12.1.tar.gz 42474 BLAKE2B 6cb333d8e429ae6b9f8c20a7486754767639693351605e85c0226ab3f1f065a549d40d69669d91f501fdf2c30346304a547e36b416d275a8bfe4ea621c0633b7 SHA512 2bcb0e4da51de9cfb5128e03c03ada77f2d4b99b0885da910584717681b96759ce4301c325cbbf43602d46746e2d37d81ed62f77dd63b33359fd5fae74d7f010
+DIST PyQtWebEngine_gpl-5.13.0.tar.gz 43939 BLAKE2B 151bfb9b7a619fe581078ce9fd42f54377673fc8873719577cddc40a7254c37b794c31baef0086897f9ed3d7914add0ac5c930dadde916ddc11e37cee428a279 SHA512 2dedffb7bde073922b357118d4bbd0327b81baaba3c69c6cf85f57401b5998bac56e01f2f7b39268b4a1e13c0b34ed116564d7f4f5975d1075d4242b1b06c065

diff --git a/dev-python/PyQtWebEngine/PyQtWebEngine-5.13.0.ebuild b/dev-python/PyQtWebEngine/PyQtWebEngine-5.13.0.ebuild
new file mode 100644 (file)
index 0000000..7ca87eb
--- /dev/null
+++ b/dev-python/PyQtWebEngine/PyQtWebEngine-5.13.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro"
+
+MY_PN=PyQtWebEngine
+MY_P=${MY_PN}_gpl-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+       SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+       SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       >=dev-python/PyQt5-5.13[gui,network,printsupport,webchannel,widgets,${PYTHON_USEDEP}]
+       >=dev-python/PyQt5-sip-4.19.14:=[${PYTHON_USEDEP}]
+       dev-qt/qtcore:5
+       dev-qt/qtwebengine:5[widgets]
+"
+DEPEND="${RDEPEND}
+       >=dev-python/sip-4.19.14[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+       configuration() {
+               local myconf=(
+                       "${PYTHON}"
+                       "${S}"/configure.py
+                       --qmake="$(qt5_get_bindir)"/qmake
+                       $(usex debug '--debug --trace' '')
+                       --verbose
+               )
+               echo "${myconf[@]}"
+               "${myconf[@]}" || die
+
+               # Fix parallel install failure
+               sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets' ${MY_PN}.pro || die
+
+               # Run eqmake to respect toolchain and build flags
+               eqmake5 -recursive ${MY_PN}.pro
+       }
+       python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+       python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+       installation() {
+               emake INSTALL_ROOT="${D}" install
+               python_optimize
+       }
+       python_foreach_impl run_in_build_dir installation
+
+       einstalldocs
+}