dev-python/twine: initial import

Closes: https://bugs.gentoo.org/567064

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
new file mode 100644 (file)
index 0000000..d86f366
--- /dev/null
+++ b/dev-python/twine/Manifest
@@ -0,0 +1 @@
+DIST twine-1.11.0.tar.gz 55301 BLAKE2B 88e88bc88a6dc8320064b3e296d85f1614d1ecf1628c8442737566ac58c3296b2292f147c0b39047a1d13a3ac98297fd7a77a0ba6fdb6ff04e59d16bc8ed463a SHA512 28e588f26b59bc9f4a8481caf2353934ad6927734762ffebb4416c147ec9e6dffb37092def20a76eb888c94b27f97e013dacc42c63e5dcda30f4290bb6c90a22

diff --git a/dev-python/twine/files/twine-1.11.0-tests.patch b/dev-python/twine/files/twine-1.11.0-tests.patch
new file mode 100644 (file)
index 0000000..386a4eb
--- /dev/null
+++ b/dev-python/twine/files/twine-1.11.0-tests.patch
@@ -0,0 +1,18 @@
+Check for python2 support first, then python3. This should help avoid importing
+the wrong module for python2 where the builtins module can be provided by the
+futures package.
+
+--- twine-1.11.0/tests/test_utils.py
++++ twine-1.11.0/tests/test_utils.py
+@@ -19,9 +19,9 @@
+ import textwrap
+ 
+ try:
+-    import builtins
+-except ImportError:
+     import __builtin__ as builtins
++except ImportError:
++    import builtins
+ 
+ import pytest
+ 

diff --git a/dev-python/twine/metadata.xml b/dev-python/twine/metadata.xml
new file mode 100644 (file)
index 0000000..3b7872f
--- /dev/null
+++ b/dev-python/twine/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="project">
+               <email>python@gentoo.org</email>
+               <name>Python</name>
+       </maintainer>
+       <upstream>
+               <remote-id type="pypi">twine</remote-id>
+               <remote-id type="github">pypa/twine</remote-id>
+       </upstream>
+</pkgmetadata>

diff --git a/dev-python/twine/twine-1.11.0.ebuild b/dev-python/twine/twine-1.11.0.ebuild
new file mode 100644 (file)
index 0000000..053b8a7
--- /dev/null
+++ b/dev-python/twine/twine-1.11.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="https://twine.readthedocs.io/ https://github.com/pypa/twine https://pypi.python.org/pypi/twine"
+SRC_URI="https://github.com/pypa/twine/archive/${PV}.tar.gz -> ${P}.tar.gz"
+# pypi tarballs don't contain test data
+#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+CDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${CDEPEND}
+       test? (
+               dev-python/pytest[${PYTHON_USEDEP}]
+               dev-python/pretend[${PYTHON_USEDEP}]
+       )
+"
+RDEPEND="${CDEPEND}
+       >=dev-python/tqdm-4.14[${PYTHON_USEDEP}]
+       >=dev-python/pkginfo-1.4.2[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+       >=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep 'dev-python/pyblake2[${PYTHON_USEDEP}]' python{2_7,3_4,3_5})
+"
+
+PATCHES=( "${FILESDIR}"/${P}-tests.patch )
+
+python_test() {
+       py.test -v tests || die "tests fail with ${EPYTHON}"
+}