dev-libs/bglibs: EAPI7, update ebuild

Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger@gmail.com>
Closes: https://bugs.gentoo.org/380649
Closes: https://github.com/gentoo/gentoo/pull/11794
Signed-off-by: Stefan Strogin <steils@gentoo.org>

diff --git a/dev-libs/bglibs/bglibs-1.106-r1.ebuild b/dev-libs/bglibs/bglibs-1.106-r1.ebuild
deleted file mode 100644 (file)
index 3964c00..0000000
--- a/dev-libs/bglibs/bglibs-1.106-r1.ebuild
+++ /dev/null
@@ -1,76 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="2"
-
-inherit toolchain-funcs eutils multilib
-
-DESCRIPTION="Bruce Guenters Libraries Collection"
-HOMEPAGE="http://untroubled.org/bglibs/"
-SRC_URI="http://untroubled.org/bglibs/archive/${P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="alpha amd64 ~arm hppa ~mips ppc ~ppc64 ~sparc x86"
-IUSE=""
-DEPEND=""
-
-src_prepare() {
-       epatch "${FILESDIR}"/${PN}-1.106-parallel-fix.patch
-       # disable tests as we want them manually
-       sed -i \
-               -e '/^all:/s|selftests||' \
-               "${S}"/Makefile
-       sed -i \
-               -e '/selftests/d' \
-               "${S}"/TARGETS
-       #sed -i \
-       #       -e 's,^libraries:,LIBS = ,g' \
-       #       -e '/^LIBS =/alibs-static: $(filter %.a,$(LIBS))' \
-       #       -e '/^LIBS =/alibs-shared: $(filter %.la,$(LIBS))' \
-       #       -e '/^LIBS =/alibraries: libs-static libs-shared' \
-       #       "${S}"/Makefile
-}
-
-src_compile() {
-       echo "${D}/usr/bin" > conf-bin
-       echo "${D}/usr/$(get_libdir)/bglibs" > conf-lib
-       echo "${D}/usr/include/bglibs" > conf-include
-       echo "${D}/usr/share/man" > conf-man
-       echo "$(tc-getCC) ${CFLAGS}" > conf-cc
-       echo "$(tc-getCC) ${LDFLAGS}" > conf-ld
-       emake || die
-}
-
-src_test() {
-       einfo "Running selftests"
-       emake selftests
-}
-
-src_install () {
-       einstall || die "install failed"
-
-       #make backwards compatible symlinks
-       dosym /usr/$(get_libdir)/bglibs /usr/$(get_libdir)/bglibs/lib
-       [ "$(get_libdir)" != "lib" ] && dosym /usr/$(get_libdir)/bglibs /usr/$(get_libdir)/bglibs/$(get_libdir)
-       dosym /usr/include/bglibs /usr/$(get_libdir)/bglibs/include
-
-       #install .so in LDPATH
-       mv "${D}"/usr/$(get_libdir)/bglibs/libbg.so.1.1.1 "${D}"/usr/$(get_libdir)/
-       mv "${D}"/usr/$(get_libdir)/bglibs/libbg-sysdeps.so.1.1.1 "${D}"/usr/$(get_libdir)/
-       dosym libbg.so.1.1.1 /usr/$(get_libdir)/libbg.so.1
-       dosym libbg.so.1.1.1 /usr/$(get_libdir)/libbg.so
-       dosym libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/libbg-sysdeps.so.1
-       dosym libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/libbg-sysdeps.so
-
-       dosym ../libbg.so.1.1.1 /usr/$(get_libdir)/bglibs/libbg.so.1.1.1
-       dosym ../libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/bglibs/libbg-sysdeps.so.1.1.1
-
-       rm "${D}"/usr/$(get_libdir)/bglibs/libbg.la
-       rm "${D}"/usr/$(get_libdir)/bglibs/libbg-sysdeps.la
-
-       dodoc ANNOUNCEMENT NEWS README ChangeLog TODO VERSION
-       dohtml doc/html/*
-       docinto latex
-       dodoc doc/latex/*
-}

diff --git a/dev-libs/bglibs/bglibs-1.106-r2.ebuild b/dev-libs/bglibs/bglibs-1.106-r2.ebuild
new file mode 100644 (file)
index 0000000..6ef63db
--- /dev/null
+++ b/dev-libs/bglibs/bglibs-1.106-r2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Bruce Guenters Libraries Collection"
+HOMEPAGE="https://untroubled.org/bglibs/
+       https://github.com/bruceg/bglibs"
+SRC_URI="https://untroubled.org/bglibs/archive/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc"
+
+BDEPEND="
+       sys-devel/libtool
+       doc? (
+               app-doc/doxygen
+               dev-tex/xcolor
+               dev-texlive/texlive-latex
+               dev-texlive/texlive-latexextra
+               virtual/latex-base
+       )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.106-parallel-fix.patch )
+
+src_prepare() {
+       default
+       # disable tests as we want them manually
+       sed -i -e '/^all:/s|selftests||' Makefile || die
+       sed -i -e '/selftests/d' TARGETS || die
+}
+
+src_configure() {
+       echo "${ED}/usr/bin" > conf-bin || die
+       echo "${ED}/usr/$(get_libdir)/bglibs" > conf-lib || die
+       echo "${ED}/usr/include/bglibs" > conf-include || die
+       echo "${ED}/usr/share/man" > conf-man || die
+       echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
+       echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
+}
+
+src_compile() {
+       default
+       if use doc; then
+               emake -C doc/latex pdf
+       fi
+}
+
+src_test() {
+       einfo "Running selftests"
+       emake selftests
+}
+
+src_install () {
+       default
+
+       #make backwards compatible symlinks
+       dosym ../../$(get_libdir)/bglibs /usr/$(get_libdir)/bglibs/lib
+       [[ "$(get_libdir)" != "lib" ]] && dosym ../../$(get_libdir)/bglibs /usr/$(get_libdir)/bglibs/$(get_libdir)
+       dosym ../../include/bglibs /usr/$(get_libdir)/bglibs/include
+
+       #install .so in LDPATH
+       mv "${ED}"/usr/$(get_libdir)/bglibs/libbg.so.1.1.1 "${ED}"/usr/$(get_libdir)/ || die
+       mv "${ED}"/usr/$(get_libdir)/bglibs/libbg-sysdeps.so.1.1.1 "${ED}"/usr/$(get_libdir)/ || die
+       dosym libbg.so.1.1.1 /usr/$(get_libdir)/libbg.so.1
+       dosym libbg.so.1.1.1 /usr/$(get_libdir)/libbg.so
+       dosym libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/libbg-sysdeps.so.1
+       dosym libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/libbg-sysdeps.so
+
+       dosym ../libbg.so.1.1.1 /usr/$(get_libdir)/bglibs/libbg.so.1.1.1
+       dosym ../libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/bglibs/libbg-sysdeps.so.1.1.1
+
+       rm "${ED}"/usr/$(get_libdir)/bglibs/libbg.la || die
+       rm "${ED}"/usr/$(get_libdir)/bglibs/libbg-sysdeps.la || die
+
+       dodoc ANNOUNCEMENT NEWS README ChangeLog TODO VERSION
+       dodoc -r doc/html/
+       if use doc; then
+               dodoc doc/latex/refman.pdf
+       fi
+}