dev-util/cvise: New package

C-Vise is a pythonic fork of dev-util/creduce.  Apparently it makes
better use of multiprocessing, and is more alive than the original.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/dev-util/cvise/Manifest b/dev-util/cvise/Manifest
new file mode 100644 (file)
index 0000000..d2add3a
--- /dev/null
+++ b/dev-util/cvise/Manifest
@@ -0,0 +1 @@
+DIST cvise-1.1.0.tar.gz 228867 BLAKE2B 08becb5ad00ef08a1f511c0bdb0cb649af1406dd035fe61f737ec6dfb5151215ae363272fc3676ce76e17234a88866ee1dd0664d82326f3ddb2ced2f1982aacf SHA512 66c09cb7e088fc36b0c36928e2eda19e7bef4fad4573fcedc06f2070136e74d7878f8056f406c2ade22fc465a75bf13dca9f4a1a319cd183187a2d66a441e661

diff --git a/dev-util/cvise/cvise-1.1.0.ebuild b/dev-util/cvise/cvise-1.1.0.ebuild
new file mode 100644 (file)
index 0000000..dd6cb68
--- /dev/null
+++ b/dev-util/cvise/cvise-1.1.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+: ${CMAKE_MAKEFILE_GENERATOR=ninja}
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Super-parallel Python port of the C-Reduce"
+HOMEPAGE="https://github.com/marxin/cvise/"
+SRC_URI="
+       https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+LLVM_MAX_SLOT=10
+DEPEND="sys-devel/clang:${LLVM_MAX_SLOT}"
+RDEPEND="${DEPEND}
+       ${PYTHON_DEPS}
+       $(python_gen_cond_dep '
+               dev-python/pebble[${PYTHON_USEDEP}]
+       ')
+       dev-util/unifdef
+       sys-devel/flex"
+BDEPEND="
+       ${PYTHON_DEPS}
+       sys-devel/flex
+       test? (
+               $(python_gen_cond_dep '
+                       dev-python/pebble[${PYTHON_USEDEP}]
+                       dev-python/pytest[${PYTHON_USEDEP}]
+               ')
+       )"
+
+llvm_check_deps() {
+       has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+src_test() {
+       cd "${BUILD_DIR}" || die
+       pytest -vv || die
+}

diff --git a/dev-util/cvise/metadata.xml b/dev-util/cvise/metadata.xml
new file mode 100644 (file)
index 0000000..0319eec
--- /dev/null
+++ b/dev-util/cvise/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="person">
+               <email>mgorny@gentoo.org</email>
+               <name>Michał Górny</name>
+       </maintainer>
+</pkgmetadata>