media-libs/waffle: Version bump to 1.6.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

diff --git a/media-libs/waffle/Manifest b/media-libs/waffle/Manifest
index f0b8ca6b3fcc403346e44fb0d153c27d41d1a76e..32f21dcd3360c7dd7ba7a49aed53a665d878737b 100644 (file)
--- a/media-libs/waffle/Manifest
+++ b/media-libs/waffle/Manifest
@@ -1 +1,2 @@
 DIST waffle-1.5.2.tar.xz 179284 BLAKE2B 40befb3e4463605e303b404677268d4758f6a43f5d83bee5e74222e2e2bf949f51444c0df68291ef0edc76be313363eca3e59e642b0356451c10703e66d96e56 SHA512 04f90f70421c88418d1d98175b552de9e036ea36b6c870a6c968c7fcc2d4cb2fa4ce08b0adcdd50f4853a7503558eae7a05ef75b292cf85d3c9796e7b342ca62
+DIST waffle-1.6.0.tar.xz 224400 BLAKE2B 458add99b346bd75dc757243b9e7db6ac269fb2c1e488333d921c640e10efd182e51e8a5e0312d334593033936adf047fc2339d21e675654d89d66edfb8922b3 SHA512 c8796ab8adf968df2c5c88e2941c83955fe41e87eb2b75b6a5cc61b0d0c06eaa44df2f255f573a51816036dc8bc3ec63f3fb51ccfb7efbfe83cdd50b3f1be13f

diff --git a/media-libs/waffle/waffle-1.6.0.ebuild b/media-libs/waffle/waffle-1.6.0.ebuild
new file mode 100644 (file)
index 0000000..a7c32a6
--- /dev/null
+++ b/media-libs/waffle/waffle-1.6.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+       EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
+       GIT_ECLASS="git-r3"
+else
+       SRC_URI="http://www.waffle-gl.org/files/release/${P}/${P}.tar.xz"
+       KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+fi
+inherit meson multilib-minimal ${GIT_ECLASS}
+
+DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
+HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc egl gbm test wayland X"
+RESTRICT="test" # gl_basic tests don't work when run from portage
+
+RDEPEND="
+       >=media-libs/mesa-9.1.6[egl?,gbm?,${MULTILIB_USEDEP}]
+       >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+       >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+       >=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+       gbm? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+       wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       >=x11-base/xcb-proto-1.8-r3[${MULTILIB_USEDEP}]
+       doc? (
+               dev-libs/libxslt
+               app-text/docbook-xml-dtd:4.2
+       )
+"
+
+src_unpack() {
+       default
+       [[ $PV = 9999* ]] && git-r3_src_unpack
+}
+
+multilib_src_configure() {
+       local emesonargs=(
+               $(meson_feature X glx)
+               $(meson_feature wayland)
+               $(meson_feature X x11_egl)
+               $(meson_feature gbm)
+               $(meson_feature egl surfaceless_egl)
+               $(meson_use test build-tests)
+               $(meson_use doc build-manpages)
+       )
+       meson_src_configure
+}
+
+multilib_src_compile() {
+       meson_src_compile
+}
+
+multilib_src_test() {
+       meson_src_test
+}
+
+multilib_src_install() {
+       meson_src_install
+
+       rm -rf ${D}/usr/share/doc/waffle1
+}