dev-python/webob: add PyPy3, fix deps and tests

* coverage isn't required to run tests but pytest is, stop using nose.
* remove intersphinx from doc.
* add missing sphinx theme dependency.

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

diff --git a/dev-python/webob/webob-1.8.5-r1.ebuild b/dev-python/webob/webob-1.8.5-r1.ebuild
new file mode 100644 (file)
index 0000000..a1502c6
--- /dev/null
+++ b/dev-python/webob/webob-1.8.5-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN=WebOb
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="WSGI request and response object"
+HOMEPAGE="https://webob.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+BDEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? (
+               >=dev-python/sphinx-1.7.5[${PYTHON_USEDEP}]
+               dev-python/alabaster[${PYTHON_USEDEP}]
+       )
+       test? (
+               >=dev-python/pytest-3.1.0[${PYTHON_USEDEP}]
+       )
+"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+       sed -i "/'sphinx.ext.intersphinx'/d" docs/conf.py || die
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       if use doc; then
+               esetup.py build_sphinx
+               HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+       fi
+}
+
+python_test() {
+       pytest -vv || die "Tests fail with ${EPYTHON}"
+}