net-libs/gssdp: Bump to 1.0.3

Package-Manager: Portage-2.3.58, Repoman-2.3.12
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

diff --git a/net-libs/gssdp/Manifest b/net-libs/gssdp/Manifest
index 6fd6307bb17e37e3910d6c9cce73b9045ec735ef..6866ff08b6ea6e620c5040b88af2c9dfe077279e 100644 (file)
--- a/net-libs/gssdp/Manifest
+++ b/net-libs/gssdp/Manifest
@@ -1 +1,2 @@
 DIST gssdp-1.0.2.tar.xz 312352 BLAKE2B 0712ce4e698fb9a455bf217863aecf4e4e87654d9b78a4e0e9c2f618a8bd9c62dd3c85ab7bd4c4400a8a658b2743bbe3a6b0d454f1b7c4a3383c893bc5ae2e7c SHA512 eac1d3db495d0433c27ad84c33c23a25b3ebdf5c85bb2d5f5b2198c00aae484f2128c22838534b9b4bf4c9787795241acafe30d00407912bdb9945422cbdc103
+DIST gssdp-1.0.3.tar.xz 316740 BLAKE2B 50293e653ec5596a986770f3ea81a244b8f9772e9d0c13df0e48f00ee34445c2fc7250702d7928e7dba081715e6d4e379d7a899905c35da84915e6b4058a3307 SHA512 ef72335c3f796aff0d3dce1781d5a0b015508f614d4a73699ebce411b0593419b40c09839ffb62e50cf9d77e16ec0e31d0e23f92d35abb4d105dea47c00a0506

diff --git a/net-libs/gssdp/gssdp-1.0.3.ebuild b/net-libs/gssdp/gssdp-1.0.3.ebuild
new file mode 100644 (file)
index 0000000..1a709e4
--- /dev/null
+++ b/net-libs/gssdp/gssdp-1.0.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 multilib-minimal vala
+
+DESCRIPTION="A GObject-based API for handling resource discovery and announcement over SSDP"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="+introspection gtk"
+
+RDEPEND="
+       >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+       >=net-libs/libsoup-2.44.2:2.4[${MULTILIB_USEDEP},introspection?]
+       gtk? ( >=x11-libs/gtk+-3.0:3 )
+       introspection? (
+               $(vala_depend)
+               >=dev-libs/gobject-introspection-1.36:= )
+       !<net-libs/gupnp-vala-0.10.3
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.14
+       sys-devel/gettext
+       >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+       # Disable functional test as it requires port that might be used by rygel to
+       # be free of use
+       sed 's/\(check_PROGRAMS.*\)test-functional$(EXEEXT)/\1/' \
+               -i "${S}"/tests/Makefile.in || die
+
+       use introspection && vala_src_prepare
+       gnome2_src_prepare
+}
+
+multilib_src_configure() {
+       ECONF_SOURCE=${S} \
+       gnome2_src_configure \
+               $(multilib_native_use_enable introspection) \
+               $(multilib_native_use_with gtk) \
+               --disable-static
+
+       if multilib_is_native_abi; then
+               # fix gtk-doc
+               ln -s "${S}"/doc/html doc/html || die
+       fi
+}
+
+multilib_src_install() {
+       gnome2_src_install
+}