net-wireless/gnome-bluetooth: bump to 3.34.0

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/net-wireless/gnome-bluetooth/Manifest b/net-wireless/gnome-bluetooth/Manifest
index c1827ae2fea12cb53c2fde77e7fba6ba8d6fa7b1..4294fc0983a45254ab2235f7501420d65bef444c 100644 (file)
--- a/net-wireless/gnome-bluetooth/Manifest
+++ b/net-wireless/gnome-bluetooth/Manifest
@@ -1 +1,2 @@
 DIST gnome-bluetooth-3.28.2.tar.xz 349456 BLAKE2B 24a8adbbd37a6a7338a10bb84fd113c3a65bb9c5ef277c9df082f10f52b9d9dc2bc3ff6182993fd85fb5f5f8269a965f0aba864f73ed8595a700a51e59242fc1 SHA512 03f66f8c5c195b10cf2c13dc93191b9f2f79adae099ddb8037ef1277731f37b8f0a42b603e8aacbe2fb108be6abf7a77a823d86d5fac62a42a53e3498d53d87e
+DIST gnome-bluetooth-3.34.0.tar.xz 351232 BLAKE2B 5ed3a2edc4d0a494013c246ce4caa64cc343c08ceeca3fbdc809591c59a59a7e269b35ba2474f38bb9ae1aba7f7b47f2d164c2be49d3e59d1af538a77a7451ab SHA512 25c99f3ac4398b24c08018cdf41a124c94312bc0b1c7202c82918134ddbdea16d6ee0980536cb45deb42ae8fa25b6e86ad21870646235108583831bf5f00926e

diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-3.34.0.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-3.34.0.ebuild
new file mode 100644 (file)
index 0000000..0eb1a32
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-3.34.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson udev xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="2/13" # subslot = libgnome-bluetooth soname version
+IUSE="gtk-doc +introspection"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+DEPEND="
+       >=dev-libs/glib-2.38:2
+       >=x11-libs/gtk+-3.12:3[introspection?]
+       media-libs/libcanberra[gtk3]
+       >=x11-libs/libnotify-0.7.0
+       virtual/libudev
+       introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+       acct-group/plugdev
+       virtual/udev
+       >=net-wireless/bluez-5
+"
+BDEPEND="
+       >=dev-util/meson-0.49.0
+       !net-wireless/bluez-gnome
+       dev-libs/libxml2:2
+       dev-util/gdbus-codegen
+       dev-util/glib-utils
+       gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+       virtual/pkgconfig
+"
+
+src_configure() {
+       local emesonargs=(
+               -Dicon_update=false
+               $(meson_use gtk-doc gtk_doc)
+               $(meson_use introspection)
+       )
+       meson_src_configure
+}
+
+src_install() {
+       meson_src_install
+       udev_dorules "${FILESDIR}"/61-${PN}.rules
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+       if ! has_version 'sys-auth/consolekit[acl]' && ! has_version 'sys-apps/systemd[acl]' ; then
+               elog "Don't forget to add yourself to the plugdev group "
+               elog "if you want to be able to control bluetooth transmitter."
+       fi
+}