media-gfx/eog: bump to 3.32.2

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/media-gfx/eog/Manifest b/media-gfx/eog/Manifest
index b91759568ccd524d9a9511791404a067f4f92fa2..21757dbb32ee5ea0e3186db1d83a1fde0e45b689 100644 (file)
--- a/media-gfx/eog/Manifest
+++ b/media-gfx/eog/Manifest
@@ -1 +1,2 @@
 DIST eog-3.28.4.tar.xz 5732396 BLAKE2B 9adf7e6793add9298dd879a0fe5ea7c736854d3a40473b2def84851a1e5a78ef84316b20b172c85c85f070278a51b06c1019aef1e5e9c5f31a87243c9229a579 SHA512 57ccb6269b2829a0606cbae08fc376bcd13028d3affe03d76c929a95faf9106dfd497872a12019158aeff5e8e101640d912cae0cece435121319820df7262c00
+DIST eog-3.32.2.tar.xz 4601712 BLAKE2B 84803acf2e2c2cb7451b357d18c7553854dd9a440ee8f951db479641ebf7fe49d8b8185124301c8b272db22d424c31197146e58d0907248cb87aa822441184d6 SHA512 c1093db4bce6bfde758a42fddc7ce7437d2adf3aa44a633b253ca3cb75c910e8862a323d182394696c617cb92114919dc576b992e7a65aa5fefb504062382d81

diff --git a/media-gfx/eog/eog-3.32.2.ebuild b/media-gfx/eog/eog-3.32.2.ebuild
new file mode 100644 (file)
index 0000000..382b119
--- /dev/null
+++ b/media-gfx/eog/eog-3.32.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="+exif gtk-doc +introspection +jpeg lcms +svg xmp tiff"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+RDEPEND="
+       >=dev-libs/glib-2.53.4:2
+       >=dev-libs/libpeas-0.7.4:=[gtk]
+       >=gnome-base/gnome-desktop-2.91.2:3=
+       >=gnome-base/gsettings-desktop-schemas-2.91.92
+       >=x11-misc/shared-mime-info-0.20
+       >=x11-libs/gdk-pixbuf-2.36.5:2[jpeg?,tiff?]
+       >=x11-libs/gtk+-3.22.0:3[introspection,X]
+       sys-libs/zlib
+
+       exif? ( >=media-libs/libexif-0.6.14 )
+       lcms? ( media-libs/lcms:2 )
+       xmp? ( media-libs/exempi:2 )
+       jpeg? ( virtual/jpeg:0 )
+       introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+       svg? ( >=gnome-base/librsvg-2.36.2:2 )
+
+       x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       gtk-doc? ( >=dev-util/gtk-doc-1.16
+               app-text/docbook-xml-dtd:4.1.2 )
+       dev-util/glib-utils
+       dev-util/itstool
+       >=sys-devel/gettext-0.19.8
+       virtual/pkgconfig
+"
+
+src_configure() {
+       local emesonargs=(
+               $(meson_use exif libexif)
+               $(meson_use lcms cms)
+               $(meson_use xmp)
+               $(meson_use jpeg libjpeg)
+               $(meson_use svg librsvg)
+               $(meson_use gtk-doc gtk_doc)
+               $(meson_use introspection)
+               -Dinstalled_tests=false
+       )
+       meson_src_configure
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+       gnome2_schemas_update
+}
+
+pkg_postrm() {
+       xdg_pkg_postrm
+       gnome2_schemas_update
+}