dev-python/shapely: initial commit, required for (testing) Flask-Admin

Package-Manager: portage-2.3.0

diff --git a/dev-python/shapely/Manifest b/dev-python/shapely/Manifest
new file mode 100644 (file)
index 0000000..c2ec85e
--- /dev/null
+++ b/dev-python/shapely/Manifest
@@ -0,0 +1 @@
+DIST Shapely-1.5.17.tar.gz 180663 SHA256 31fee47d9208078a19f40a451c0c99c085d16343e66cbd0dd5af0af6f48cfc3a SHA512 eea241942ffbf377001445fab4017c9a2746d6bc0baa6c801a08ca95e608bbdaea7ad9568f00cbecdb559e634402bc6d213ebccb4074e59325e1cc4b3771626d WHIRLPOOL e28ffd196edc0bdfe2da86351410fb57bda774ecf7283c890f002261ab586351625a7d15aede0310de03175330fa522da693e8397c74857d606ed23a2de78547

diff --git a/dev-python/shapely/metadata.xml b/dev-python/shapely/metadata.xml
new file mode 100644 (file)
index 0000000..913fbc6
--- /dev/null
+++ b/dev-python/shapely/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">Shapely</remote-id>
+  </upstream>
+</pkgmetadata>

diff --git a/dev-python/shapely/shapely-1.5.17.ebuild b/dev-python/shapely/shapely-1.5.17.ebuild
new file mode 100644 (file)
index 0000000..430e17a
--- /dev/null
+++ b/dev-python/shapely/shapely-1.5.17.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1
+
+MY_PN="Shapely"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Geometric objects, predicates, and operations"
+HOMEPAGE=" https://github.com/Toblerity/Shapely"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND=">=sci-libs/geos-3.3
+       dev-python/numpy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       dev-python/cython[${PYTHON_USEDEP}]
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+       # fix install path for Cython definition file
+       sed -i \
+               -e "s|\(data_files.*\)'shapely'|\1'share/shapely'|" \
+               setup.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       distutils_install_for_testing
+       cd "${TEST_DIR}/lib" || die
+       cp -r "${S}/tests" . || die
+       py.test tests || die
+}